bintray-release.gradle

apply plugin: 'com.novoda.bintray-release'
apply plugin: 'maven'
// This generates sources.jar
task sourcesJar(type: Jar) {
    from sourceSets.main.java.srcDirs
    from sourceSets.main.groovy.srcDirs
    archiveClassifier.convention('sources')
}

// This generates javadoc.jar
task javadocJar(type: Jar, dependsOn: javadoc) {
    from javadoc.destinationDir
    archiveClassifier.convention('javadoc')
}

artifacts {
    archives javadocJar
    archives sourcesJar
}

// javadoc configuration
javadoc {
    options {
        encoding "UTF-8"
        charSet 'UTF-8'
        author true
    }
}

afterEvaluate {
    Task bintrayUploadTask = tasks.findByName('bintrayUpload')
    Task uploadArchivesTask = tasks.findByName('uploadArchives')
    if (bintrayUploadTask != null && uploadArchivesTask != null) {
        bintrayUploadTask.dependsOn uploadArchivesTask
    }
    tasks.withType(Javadoc) {
        options.addStringOption('Xdoclint:none', '-quiet')
        options.addStringOption('encoding', 'UTF-8')
    }
}