build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'

ext.buildProps = file "build.properties"
 
buildProps.withReader {
    def prop = new Properties()
    prop.load(it)
    ext.config = new ConfigSlurper().parse prop
}

version = "${config.version.mod}"
group = "quadrum"
archivesBaseName = "Quadrum-${config.version.minecraft}"

minecraft {
    version = "${config.version.minecraft}-${config.version.forge}"
    runDir = "run"
    replace "@VERSION@", config.version.mod
}

processResources {
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        expand 'mod_version':project.version, 'minecraft_version':project.minecraft.version
    }
        
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

def commonManifest = {
    attributes 'FMLAT': 'quadrum_at.cfg'
}

jar {
    classifier = 'universal'
    manifest commonManifest
}

task devJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'dev'
    manifest commonManifest
}

task sourceJar(type: Jar) {
    from sourceSets.main.java
    classifier = 'src'
}

artifacts {
    archives sourceJar, devJar
}