build.gradle

plugins {
    id "java-library"
    id "maven"
    id "signing"
}

group "dev.dewy"
version "1.5.1"

repositories {
    mavenCentral()

    maven {
        name "mojang"
        url "https://libraries.minecraft.net/"
    }
}

dependencies {
    implementation "org.apache.commons:commons-lang3:$lang3"
    implementation "com.google.code.gson:gson:$gson"

    compileOnly "org.projectlombok:lombok:$lombok"
    annotationProcessor "org.projectlombok:lombok:$lombok"

    testCompileOnly "org.projectlombok:lombok:$lombok"
    testAnnotationProcessor "org.projectlombok:lombok:$lombok"
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = "sources"
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = "javadoc"
    from javadoc.destinationDir
}

artifacts {
    archives jar
    archives sourcesJar
    archives javadocJar
}

signing {
    if (project.hasProperty("signing.keyId")) {
        sign configurations.archives
    }
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment {
                MavenDeployment deployment -> signing.signPom(deployment)
            }

            repository(url: "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: hasProperty('ossrhUsername')?ossrhUsername:'', password: hasProperty('ossrhPassword')?ossrhPassword:'')
            }

            pom.project {
                name = "nbt"
                description = "Flexible and intuitive library for reading and writing Minecraft's NBT format, with emphasis on custom tags."
                url = "https://github.com/iBuyMountainDew/nbt"

                packaging "jar"

                licenses {
                    license {
                        name = "MIT License"
                        url = "https://github.com/iBuyMountainDew/nbt/blob/main/LICENSE.md"
                    }
                }

                developers {
                    developer {
                        id = "dewy"
                        name = "Dewy REDACTED"
                        email = "dewy@dewy.dev"
                    }
                }

                scm {
                    connection "scm:git:git://github.com/iBuyMountainDew/nbt.git"
                    developerConnection "scm:git:ssh://github.com/iBuyMountainDew/nbt.git"
                    url "https://github.com/iBuyMountainDew/nbt"
                }
            }
        }
    }
}