build.gradle

buildscript {
    repositories {
        mavenCentral()
    }
}

plugins {
    id 'java-library'
    id 'maven-publish'
    id 'signing'
}

group = 'de.bwaldvogel'
version = '2.5.1'

sourceCompatibility = 1.8
targetCompatibility = 1.8

compileJava.options.encoding = 'UTF-8'

ext {
    title = 'log4j-systemd-journal-appender'
    description = 'Log4j appender for systemd journal.'
    url = 'https://www.github.com/bwaldvogel/log4j-systemd-journal-appender'
}

jar {
    manifest {
        attributes 'Implementation-Title': title, 'Implementation-Version': project.version
    }
}

task sourceJar(type: Jar) {
    archiveClassifier = "sources"
    from sourceSets.main.allJava
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    archiveClassifier = "javadoc"
    from javadoc.destinationDir
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            groupId = 'de.bwaldvogel'
            artifactId = 'log4j-systemd-journal-appender'
            version = project.version
            pom {
                name = title
                description = 'Log4j appender for systemd journal.'
                url = 'https://github.com/bwaldvogel/log4j-systemd-journal-appender'
                inceptionYear = '2014'

                licenses {
                    license {
                        name = 'The BSD License'
                        url = 'http://www.opensource.org/licenses/bsd-license.php'
                        distribution = 'repo'
                    }
                }
                developers {
                    developer {
                        id = 'bwaldvogel'
                        name = 'Benedikt Waldvogel'
                        email = 'mail@bwaldvogel.de'
                    }
                }
                scm {
                    url = 'git@github.com:bwaldvogel/log4j-systemd-journal-appender.git'
                    connection = 'scm:git:git@github.com:bwaldvogel/log4j-systemd-journal-appender.git'
                    developerConnection = 'scm:git:git@github.com:bwaldvogel/log4j-systemd-journal-appender.git'
                }
            }

            from components.java

            artifact sourceJar
            artifact javadocJar

            versionMapping {
                usage('java-api') {
                    fromResolutionOf('runtimeClasspath')
                }
                usage('java-runtime') {
                    fromResolutionResult()
                }
            }
        }
    }
    repositories {
        maven {
            url "https://oss.sonatype.org/service/local/staging/deploy/maven2"
            credentials {
                username = project.hasProperty('nexusUsername') ? project.property('nexusUsername') : System.getenv('NEXUS_USERNAME')
                password = project.hasProperty('nexusPassword') ? project.property('nexusPassword') : System.getenv('NEXUS_PASSWORD')
            }
        }
    }
}

signing {
    useGpgCmd()
    sign publishing.publications.mavenJava
}

repositories {
    mavenCentral()
}

wrapper {
    gradleVersion = '7.3.3'
    distributionType = Wrapper.DistributionType.ALL
}

dependencies {
    implementation group: 'org.apache.logging.log4j', name: 'log4j-api', version: 'latest.release'
    implementation group: 'org.apache.logging.log4j', name: 'log4j-core', version: 'latest.release'
    implementation group: 'net.java.dev.jna', name: 'jna', version: 'latest.release'

    testImplementation group: 'junit', name: 'junit', version: 'latest.release'
    testImplementation group: 'org.mockito', name: 'mockito-core', version: 'latest.release'

    components.all { ComponentMetadataDetails details ->
        details.statusScheme = ['candidate', 'release']
        if (details.id.version =~ /(?i).+(-|\.)(CANDIDATE|RC|BETA|ALPHA|PR|M\d+).*/) {
            details.status = 'candidate'
        } else {
            details.status = 'release'
        }
    }

    dependencyLocking {
        lockAllConfigurations()
    }

    task resolveAndLockAll {
        doFirst {
            assert gradle.startParameter.writeDependencyLocks
        }
        doLast {
            configurations.findAll {
                // Add any custom filtering on the configurations to be resolved
                it.canBeResolved
            }.each { it.resolve() }
        }
    }
}