build.gradle

plugins {
    id 'java'
    id 'xyz.jpenilla.run-paper' version '2.1.0'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

group = 'at.noahb'
version = '0.1.1'

repositories {
    mavenLocal()
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/groups/public/"
    }
    maven {
        name = "codemc"
        url = "https://repo.codemc.org/repository/maven-public/"
    }
}

dependencies {
    compileOnly "io.papermc.paper:paper-api:1.20.2-R0.1-SNAPSHOT"
    implementation "dev.jorel:commandapi-bukkit-shade:9.2.0"
}

def targetJavaVersion = 17
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release = targetJavaVersion
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

shadowJar {
    dependencies {
        include dependency("dev.jorel:commandapi-bukkit-shade:9.2.0")
    }

    relocate("dev.jorel.commandapi", "at.noahb.commandapi")

    archiveFileName = "PrimaryRespawn-${version}.jar"
}

tasks {
    runServer {
        dependsOn('shadowJar')
        minecraftVersion("1.20.2")
    }
}