Power consumption of ATtiny1614 is too high in deep sleep after using SPI

[strange-v]

I'm migrating a project from 328P to ATtiny1614 and have issues with power consumption. The bare microcontroller in a deep sleep consumes less than 1 µA, but after adding the RFM69 radio, the consumption is ~19 µA. The problem is not in the RFM69 itself, as with 328P, I got ~5µA in total, including other sensors.

I had similar issues with the previous MC, but they were solved by disabling some periphery:

  ADCSRA = 0;
  power_adc_disable();
  power_spi_disable();
  power_timer0_disable();
  power_timer1_disable();
  power_timer2_disable();
  power_twi_disable();
  power_usart0_disable();

I've tried a similar approach here, but with no luck (probably, I'm disabling not enough)

  ADC0.CTRLA &= ~ADC_ENABLE_bm;
  SPI0.CTRLA &= ~SPI_ENABLE_bm;
  TWI0.CTRLA &= ~TWI_ENABLE_bm;
  TCA0.SPLIT.CTRLA &= ~TCA_SPLIT_ENABLE_bm;
  TCD0.CTRLA &= ~TCD_ENABLE_bm;

Any idea on what else should be disabled? Or any other suggestions?

PS
The code I use for testing:

#include <Arduino.h>
#include <RFM69.h>
#include <periphery.h>
#include <functions.h>

RFM69 radio(PIN_PA4, PIN_PA7);
NodeData data{RADIO_NODE_TYPE, 0, 0};

ISR(RTC_PIT_vect)
{
  RTC.PITINTFLAGS = RTC_PI_bm;
}

void initRTC()
{
  while (RTC.STATUS > 0)
  {
  }
  RTC.CLKSEL = RTC_CLKSEL_INT1K_gc;
  RTC.PITINTCTRL = RTC_PI_bm;
  RTC.PITCTRLA = RTC_PERIOD_CYC32768_gc
                 | RTC_PITEN_bm;
}

void setup()
{
  pinMode(PIN_PA7, INPUT);
  pinMode(PIN_PA0, INPUT_PULLUP);
  pinMode(PIN_PA5, INPUT_PULLUP);
  pinMode(PIN_PB0, INPUT_PULLUP);
  pinMode(PIN_PB1, INPUT_PULLUP);
  pinMode(PIN_PB2, INPUT_PULLUP);
  pinMode(PIN_PB3, INPUT_PULLUP);

#ifdef RADIO_NODE_DEBUG_LED
  pinMode(RADIO_NODE_DEBUG_LED, OUTPUT);
  digitalWrite(RADIO_NODE_DEBUG_LED, LOW);
#endif
  pinMode(PIN_REED_SWITCH, INPUT_PULLUP);

  bool radioState = radio.initialize(RF69_868MHZ, RADIO_NODE_ID, RADIO_NETWORK_ID);
#ifdef RADIO_NODE_DEBUG_LED
  blink(radioState ? 1 : 3);
#endif

  radio.setHighPower(true);
  radio.encrypt(RADIO_ENCRYPTION_KEY);
  radio.setPowerLevel(RADIO_POWER_LEVEL);
  radio.sleep();

  initRTC();
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);
  sleep_enable();
  sei();
}

void loop()
{
  data.state = !digitalRead(PIN_PA6);
  
  ADC0.CTRLA &= ~ADC_ENABLE_bm;
  SPI0.CTRLA &= ~SPI_ENABLE_bm;
  TWI0.CTRLA &= ~TWI_ENABLE_bm;
  TCA0.SPLIT.CTRLA &= ~TCA_SPLIT_ENABLE_bm;
  TCD0.CTRLA &= ~TCD_ENABLE_bm;
  sleep_cpu();
  SPI0.CTRLA |= SPI_ENABLE_bm;
  TWI0.CTRLA |= TWI_ENABLE_bm;
  ADC0.CTRLA |= ADC_ENABLE_bm;
  TCD0.CTRLA |= TCD_ENABLE_bm;
}

[MX682X]

you could try disabling the input Buffers alltogether, like:
pinConfigure(PIN_PA0, (PIN_PULLUP_ON | PIN_ISC_DISABLE)); , etc. This includes the digital Output pins aswell.
I recomend not to touch (or rather Enable) TWI, TCA and TCD. Those are not active in Power Down and you might end up enabling them in non-sleep mode. (Millis is using TCB1).

[strange-v]

Thank you. I've removed all that optimization, but I'll disable everything not needed on the setup to lower the power consumption in active mode.

[strange-v]

There were two issues:

1. One of the boards had weird power consumption (possibly due to the improper cleaning of flux residue).
2. The second board had PIN_PA7 configured as input, but the pin was floating (must be connected to RFM69 interrupt).

After connecting the PIN_PA7, I see 2 µA on the multimeter. It is already better than with 328P, but I'll try to squeeze more when Power Profiler Kit II arrives.