build.gradle

plugins {
    id 'dev.architectury.loom' version '1.6-SNAPSHOT' apply false
    id 'architectury-plugin' version '3.4-SNAPSHOT'
    id 'com.github.johnrengelman.shadow' version '8.1.1' apply false
}

architectury {
    minecraft = project.minecraft_version
}

allprojects {
    group = rootProject.maven_group
    version = rootProject.mod_version
}

subprojects {
    apply plugin: 'dev.architectury.loom'
    apply plugin: 'architectury-plugin'
    apply plugin: 'maven-publish'
    apply plugin: 'com.github.johnrengelman.shadow'

    configurations {

        shadowBundle {
            canBeResolved = true
            canBeConsumed = false

        }
    }

    base {
        // Set up a suffixed format for the mod jar names, e.g. `example-fabric`.
        archivesName = "$rootProject.archives_name-$project.name"
    }

    repositories {
        // Add repositories to retrieve artifacts from in here.
        // You should only use this when depending on other mods because
        // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
        // See https://docs.gradle.org/current/userguide/declaring_repositories.html
        // for more information about repositories.
    }

    loom {
        silentMojangMappingsLicense()
    }

    dependencies {
        minecraft "net.minecraft:minecraft:$rootProject.minecraft_version"
        mappings loom.officialMojangMappings()

        shadowBundle(implementation("io.prometheus:simpleclient:0.14.1"))
        shadowBundle(implementation("io.prometheus:simpleclient_httpserver:0.14.1"))
        shadowBundle(implementation("io.prometheus:simpleclient_common:0.14.1"))
        shadowBundle(implementation("io.prometheus:simpleclient_hotspot:0.14.1"))

        tasks.withType(ProcessResources).configureEach {
            var replaceProperties = [
                    minecraft_version      : minecraft_version,
                    architectury_api_version: architectury_api_version,
                    mod_id                 : mod_id,
                    mod_name               : mod_name,
                    mod_license            : mod_license,
                    mod_version            : mod_version,
                    mod_authors            : mod_authors,
                    mod_description        : mod_description,
                    maven_group            : maven_group,
                    mod_contact            : mod_contact,
                    mod_git                : mod_git,

                    //Fabric
                    fabric_java            : fabric_java,
                    fabric_fabricapi       : fabric_fabricapi,
                    fabric_api_version     : fabric_api_version,
                    fabric_loader_version  : fabric_loader_version,

                    //NeoForge
                    neoforge_loaderversion : neoforge_loaderversion,
                    neoforge_loaderrange   : neoforge_loaderrange,
                    neoforge_version       : neoforge_version,
            ]
            inputs.properties replaceProperties

            filesMatching(['META-INF/neoforge.mods.toml', 'fabric.mod.json']) {
                expand replaceProperties
            }
        }
    }

    shadowJar {
        configurations = [project.configurations.shadowBundle]
        archiveClassifier = 'dev-shadow'

        //    relocate 'redis.clients', 'net.stonebound.shaded.redis.clients'
        relocate 'io.prometheus', 'net.stonebound.sbprometheus.shaded.io.prometheus'

        dependencies {
            exclude(dependency("org.slf4j:.*:.*"))
            exclude(dependency("org.jetbrains:.*:.*"))
        }
    }

    java {
        // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
        // if it is present.
        // If you remove this line, sources will not be generated.
        withSourcesJar()

        sourceCompatibility = JavaVersion.VERSION_21
        targetCompatibility = JavaVersion.VERSION_21
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.release = 21
    }

    // Configure Maven publishing.
    publishing {
        publications {
            mavenJava(MavenPublication) {
                artifactId = base.archivesName.get()
                from components.java
            }
        }

        // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
        repositories {
            // Add repositories to publish to here.
            // Notice: This block does NOT have the same function as the block in the top level.
            // The repositories here will be used for publishing your artifact, not for
            // retrieving dependencies.
        }
    }
}