common-android-library.gradle

import ru.redmadrobot.movie_app.Dependencies
import ru.redmadrobot.movie_app.TestDependencies

apply plugin: 'kotlin-android'
apply plugin: 'kotlin-android-extensions'
apply plugin: 'kotlin-kapt'

apply plugin: "androidx.navigation.safeargs.kotlin"

apply plugin: 'de.mannodermaus.android-junit5'

apply from: rootProject.file('versions.gradle')

android {
    compileSdkVersion build_versions.compile_sdk
    buildToolsVersion build_versions.build_tools
    defaultConfig {
        minSdkVersion build_versions.min_sdk

        vectorDrawables.useSupportLibrary = true

        kapt.arguments {
            arg("room.schemaLocation", "$projectDir/schemas".toString())
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = "1.8"
    }

    sourceSets {
        androidTest.assets.srcDirs += files("$projectDir/schemas".toString())
        it.each {
            it.java.srcDirs += "src/$it.name/kotlin"
        }
    }

    viewBinding {
        enabled = true
    }

    testOptions {
        unitTests.returnDefaultValues = true
        junitPlatform {
            filters {
                engines {
                    include 'spek2'
                }
            }
        }
        unitTests.all {
            testLogging.events = ["passed", "skipped", "failed"]
        }
    }

    packagingOptions {
            exclude "META-INF/LICENSE*"
    }
}

dependencies {
    implementation(
            Dependencies.Tools.Timber,
            Dependencies.Tools.Glide,
            Dependencies.Tools.Groupie,
            Dependencies.Tools.Lottie
    )

    testImplementation(TestDependencies.testImpl)
    testRuntimeOnly(TestDependencies.testRuntime)

    androidTestImplementation(TestDependencies.androidTestImpl)
}