build.gradle

// SETUP BUILDSCRIPT ///////////////////////////////////////////////////////////
buildscript {
  repositories {
    jcenter()
    maven {
      url 'https://plugins.gradle.org/m2/'
    }
  }

  dependencies {
    classpath 'org.xtext:xtext-gradle-plugin:1.0.19'
    classpath 'com.netflix.nebula:gradle-extra-configurations-plugin:3.0.3'
  }
}

task wrapper(type: Wrapper) {
	gradleVersion = '4.0'
}

// CONFIGURE PROJECTS ///////////////////////////////////////////////////
subprojects {
  apply plugin: 'eclipse'
  apply plugin: 'java'
  apply plugin: 'org.xtext.xtend'
  apply plugin: 'maven-publish'
  apply plugin: 'jacoco'

  sourceCompatibility = javaVersion
  targetCompatibility = javaVersion

  eclipse.project.name = rootProject.name + '-' + project.name

  repositories {
    mavenLocal()
    mavenCentral()
  }

  dependencies {
    compile "org.eclipse.xtend:org.eclipse.xtend.lib:${xtendVersion}"
    compile "org.slf4j:slf4j-api:${slf4jVersion}"
    testCompile "ch.qos.logback:logback-classic:${logbackVersion}"
    testCompile "junit:junit:${junitVersion}"
  }

  task sourcesJar( type: Jar, dependsOn: classes ) {
    classifier = 'sources'
    from sourceSets.main.allSource
  }

  task javadocJar( type: Jar, dependsOn: javadoc ) {
    classifier = 'javadoc'
    from javadoc.destinationDir
  }

  tasks.withType( Javadoc ) {
    if ( JavaVersion.current().isJava8Compatible() ) {
      options.addStringOption( 'Xdoclint:none', '-quiet' )
    }
  }

  task install( dependsOn: publishToMavenLocal )

  jacoco {
    toolVersion = '0.7.6.201602180812'
  }

  jacocoTestReport {
    group = "Reporting"
    description = "Generate Jacoco coverage reports after running tests."
    reports.html.enabled true
  }

  publishing {
    publications {
      mavenJava( MavenPublication ) {
        artifactId rootProject.name + '-' + project.name
        from components.java
        artifact sourcesJar
        artifact javadocJar
        pom.withXml {
          asNode().dependencies.'*'.each() {
            it.scope*.value = 'compile'
          }
        }
      }
    }
  }
}

project( 'annotations' ) {
  dependencies {
  }
}

project( 'annotations-test' ) {
  dependencies {
    compile project(":annotations")
  }
}

project( 'core' ) {
  dependencies {
    compile project(":annotations")
  }
}

project( 'test' ) {
  dependencies {
    compile project( ':core' )
    compile "junit:junit:${junitVersion}"
  }
}