-
Notifications
You must be signed in to change notification settings - Fork 6
/
Copy pathspeechd-braille.el
193 lines (143 loc) · 6.47 KB
/
speechd-braille.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
;;; speechd-braille.el --- Emacs braille emulator driver -*- lexical-binding: t -*-
;; Copyright (C) 2012-2021 Milan Zamazal <[email protected]>
;; Copyright (C) 2004-2008 Brailcom, o.p.s.
;; Author: Milan Zamazal <[email protected]>
;; COPYRIGHT NOTICE
;;
;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;;
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Code:
(require 'eieio)
(require 'braille)
(require 'mmanager)
(require 'speechd-common)
(require 'speechd-out)
(defgroup speechd-braille ()
"speechd-el Braille output."
:group 'speechd-el)
(defcustom speechd-braille-display-time 3
"How many seconds to display a message before displaying the next one."
:type 'number
:group 'speechd-braille)
(defvar speechd-braille--vetoed-icons '("message"))
(defvar speechd-braille--paused-messages '())
(defvar speechd-braille--last-message nil)
(defvar speechd-braille--last-message-time 0)
(defvar speechd-braille--display-timer nil)
(defun speechd-braille--time ()
(funcall (if (fboundp 'time-to-seconds)
#'time-to-seconds
;; taken from time-date.el
#'(lambda (time)
(+ (* (car time) 65536.0)
(cadr time)
(/ (or (nth 2 time) 0) 1000000.0))))
(current-time)))
(defun speechd-braille--display (manager message &optional sticky)
(speechd-braille--stop manager)
(apply (mmanager-get manager 'braille-display) message)
(setq speechd-braille--last-message message)
(setq speechd-braille--last-message-time (speechd-braille--time))
(unless sticky
(setq speechd-braille--display-timer
(run-at-time speechd-braille-display-time nil
#'mmanager-next manager))))
(defun speechd-braille--stop (_manager)
(when speechd-braille--display-timer
(cancel-timer speechd-braille--display-timer))
(setq speechd-braille--display-timer nil))
(defun speechd-braille--pause (_manager)
(push speechd-braille--last-message speechd-braille--paused-messages))
(defun speechd-braille--resume (manager)
(let ((message (pop speechd-braille--paused-messages)))
(when message
(speechd-braille--display manager message))))
(defun speechd-braille--busy (_manager)
(and speechd-braille--display-timer
(< (- (speechd-braille--time) speechd-braille--last-message-time)
speechd-braille-display-time)))
(defun speechd-braille--create-manager (display-func)
(let ((manager (mmanager-create display-func
#'speechd-braille--stop
#'speechd-braille--pause
#'speechd-braille--resume
#'speechd-braille--busy)))
(mmanager-put manager 'braille-display #'braille-display)
manager))
(defun speechd-braille--maybe-enqueue (driver text message)
(with-slots (manager priority) driver
(if speechd-update
(mmanager-enqueue manager speechd-client-name
(speechd-braille--make-message
driver
(speechd-out-update-text speechd-update)
(speechd-out-update-cursor speechd-update))
priority (speechd-out-update-group speechd-update))
(unless (string= text "")
(mmanager-enqueue manager speechd-client-name message priority)))))
;;; Interface functions
(defclass speechd-braille-emu-driver (speechd-driver)
((name :initform 'braille-emu)
(manager)
(priority)))
(cl-defmethod initialize-instance :after
((this speechd-braille-emu-driver) _slots)
(progn
(oset this priority speechd-default-text-priority)
(oset this manager (speechd-braille--create-manager #'speechd-braille--display))))
(cl-defmethod speechd-braille--make-message
((_driver speechd-braille-emu-driver) text cursor)
(list text cursor))
(cl-defmethod speechd.cancel ((driver speechd-braille-emu-driver) _all)
(mmanager-cancel (slot-value driver 'manager) speechd-client-name))
(cl-defmethod speechd.stop ((driver speechd-braille-emu-driver) _all)
(mmanager-next (slot-value driver 'manager)))
(cl-defmethod speechd.pause ((_driver speechd-braille-emu-driver) _all)
;; do nothing
)
(cl-defmethod speechd.resume ((_driver speechd-braille-emu-driver) _all)
;; do nothing
)
(cl-defmethod speechd.repeat ((_driver speechd-braille-emu-driver))
;; do nothing
)
(cl-defmethod speechd.block ((driver speechd-braille-emu-driver) function)
(mmanager-start-block (slot-value driver 'manager) speechd-client-name
(slot-value driver 'priority))
(unwind-protect (funcall function)
(mmanager-finish-block (slot-value driver 'manager) speechd-client-name)))
(cl-defmethod speechd.text ((driver speechd-braille-emu-driver) text cursor _markers)
(speechd-braille--maybe-enqueue
driver text (speechd-braille--make-message driver text cursor)))
(cl-defmethod speechd.icon ((driver speechd-braille-emu-driver) icon)
(unless (member icon speechd-braille--vetoed-icons)
(speechd-braille--maybe-enqueue
driver icon (speechd-braille--make-message driver icon nil))))
(cl-defmethod speechd.char ((driver speechd-braille-emu-driver) char)
(let ((text (char-to-string char)))
(speechd-braille--maybe-enqueue
driver text (speechd-braille--make-message driver text nil))))
(cl-defmethod speechd.key ((driver speechd-braille-emu-driver) key)
(let ((key-string (if (numberp key) (key-description (list key)) (format "%s" key))))
(speechd-braille--maybe-enqueue
driver key-string (speechd-braille--make-message driver key-string nil))))
(cl-defmethod speechd.set ((driver speechd-braille-emu-driver) parameter value)
(when (eq parameter 'priority)
(setf (slot-value driver 'priority) value)))
(cl-defmethod speechd.shutdown ((_driver speechd-braille-emu-driver))
;; do nothing
)
(speechd-out-register-driver (make-instance 'speechd-braille-emu-driver))
;;; Announce
(provide 'speechd-braille)
;;; speechd-braille.el ends here