Skip to content
New issue

Have a question about this project? Sign up for a free GitHub account to open an issue and contact its maintainers and the community.

Sign up for GitHub

By clicking “Sign up for GitHub”, you agree to our terms of service and privacy statement. We’ll occasionally send you account related emails.

Already on GitHub? Sign in to your account

Jump to bottom

replace some samples part 2: (sometimes) fox #665

Open
tjingboem opened this issue Jan 26, 2023 · 11 comments
Open

replace some samples part 2: (sometimes) fox #665

tjingboem opened this issue Jan 26, 2023 · 11 comments
Assignees
@tjingboem

Comments

@tjingboem
Copy link
Member

tjingboem commented Jan 26, 2023 •
edited
Loading

Sometimes(!) the fox can be replaced by Mathews.wav or perhaps marimba.aif or singFemale.aif
All these samples can be fund in manual/examples already.

  • ATSadd-2.csd
  • ATSadd.csd
  • ATSaddnz-2.csd
  • ATSinfo.csd
  • ATSinterpread.csd
  • ATSread-musical.csd
  • ATSread.csd
  • ATSsinnoi-2.csd
  • PartikkelExample1.csd --> Mathews
  • allpole-2.csd--> Mathews
  • allpole.csd
  • atsa.csd
  • b.csd
  • capB.csd
  • ceps.csd
  • cepsinv.csd
  • clear.csd
  • cmplxprod.csd
  • convolve.csd
  • cross2.csd
  • cudanal.csd
  • delay.csd --> Mathews
  • diff.csd
  • exciter.csd --> Mathews
  • filelen.csd --> Mathews
  • filenchnls.csd
  • filescal.csd
  • filevalid.csd --> fox
  • fin.csd
  • flooper.csd --> fox
  • flooper2.csd --> fox
  • fog.csd
  • framebuffer.csd
  • ftlen.csd
  • gainslider.csd
  • gen19.csd --> fox
  • gen20.csd --> marimba
  • gen23.csd --> fox
  • gen53.csd
  • genwave.csd
  • granule.csd
  • hetro.csd
  • integ.csd
  • irfft.csd
  • limit.csd
  • liveconv.csd --> Mathews
  • lpcanal-2.csd --> Mathews
  • lpcanal.csd --> Mathews
  • lpcfilter-2.csd --> Mathews
  • lpcfilter.csd --> Mathews
  • lpfreson.csd
  • lpread.csd
  • lpreson-2.csd
  • lpreson.csd
  • lpslot.csd
  • mac.csd
  • maca.csd
  • mags.csd
  • mfb.csd
  • mincer.csd
  • mirror.csd
  • nsamp.csd
  • opcode_f.csd
  • outch-3.csd
  • outleta.csd
  • partials.csd
  • partikkel-2.csd --> Mathews
  • passign.csd
  • paulstretch.csd
  • pconvolve.csd
  • phs.csd
  • pitch.csd
  • pitchamdf.csd
  • plltrack.csd
  • pol2rect.csd
  • port.csd
  • poscil3-file.csd
  • pow.csd
  • powoftwo.csd
  • printf.csd
  • ptrack.csd
  • pvadd.csd
  • pvanal.csd
  • pvinterp.csd
  • pvoc.csd --> Mathews
  • pvread.csd
  • pvsadsyn.csd
  • pvsanal.csd
  • pvsarp2.csd
  • pvsbandp.csd
  • pvsbandr.csd
  • pvsbandwidth.csd
  • pvsbin.csd
  • pvsblur.csd
  • pvsbuffer
  • pvsbuffer.csd
  • pvscale.csd
  • pvscent.csd
  • pvsceps.csd
  • pvscfs.csd
  • pvsdemix.csd
  • pvsdiskin.csd
  • pvsdisp.csd
  • pvsfilter.csd
  • pvsfreeze.csd
  • pvsftr.csd
  • pvsftw.csd
  • pvshift.csd
  • pvsinfo.csd
  • pvsinit.csd
  • pvslpc.csd
  • pvsmaska.csd
  • pvsmooth.csd
  • pvsmorph.csd
  • pvstanal.csd
  • pvsvoc.csd
  • pvswarp.csd
  • pvsynth.csd
  • raises.csd
  • readscore.csd
  • rect2pol.csd
  • repluck-advanced.csd
  • resonbnk.csd
  • resyn.csd
  • rfft.csd
  • rms.csd
  • scans-2.csd
  • shiftin.csd
  • shiftout.csd
  • sinsyn.csd
  • skf.csd
  • sndwarp.csd --> Mathews
  • spf.csd
  • spsend.csd
  • strcpyk.csd
  • streson.csd
  • strget.csd
  • strindexk.csd
  • syncgrain.csd --> Mathews
  • tabifd.csd
  • tableikt.csd
  • tableseg_tablexseg.csd
  • taninv2-advanced.csd
  • temposcal.csd
  • toot8.csd
  • toot9.csd
  • trcross.csd
  • trhighest.csd
  • trmix.csd
  • trscale.csd
  • trshift.csd
  • tvconv.csd
  • unwrap.csd
  • upsamp.csd
  • valpass.csd
  • vdelayx.csd --> Mathews
  • vdelayxq.csd --> Mathews
  • vdelayxwq.csd --> Mathews
  • vincr.csd
  • vpow-2.csd
  • vpow_i-2.csd
  • vpvoc.csd
  • wgpluck.csd
  • window.csd
  • wrap.csd
@tjingboem tjingboem self-assigned this Jan 26, 2023
@csounder
Copy link

csounder commented Jan 26, 2023 via email

@tjingboem
Copy link
Member Author

syncgrain

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac  ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o syncgrain.wav -W ;;; for file output any platform
</CsOptions> 
<CsInstruments>

sr = 44100 
ksmps = 32 
0dbfs  = 1 
nchnls = 2
  
instr 1
		
iolaps  = 2
igrsize = 0.04
ifreq   = iolaps/igrsize
ips     = 1/iolaps

istr    = .3   /* timescale  */
ipitch  = p4   /* pitchscale */

asig	syncgrain 1, ifreq, ipitch, igrsize, ips*istr, 1, 2, iolaps
	outs	  asig, asig 

endin
</CsInstruments>
<CsScore>
f1 0 0 1 "Mathews.wav" 0 0 0	;deferred table
f2   0   8192   20   2   1

i1 0 11 1
i1 + 11 4
i1 + 11 .8
e
</CsScore>
</CsoundSynthesizer>

@tjingboem
Copy link
Member Author

pvoc

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   -m0  --limiter=.95 ;;;realtime audio out, with limiter protection
; For Non-realtime ouput leave only the line below:
; -o pvoc.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

; by Menno Knevel 2023

gilen  filelen "Mathews.wav"	    ; get length of impulse soundfile

; analyze sound file and output result to pvoc-ex file
ires system_i 1,{{ pvanal Mathews.wav Mathews1.pvx }}          ; default settings

instr 1 ; untreated signal
asig    diskin2   "Mathews.wav", 1
prints  "\n---***YOU NOW HEAR THE UNTREATED SOUND SAMPLE***---\n"
outs    asig*.8, asig*.8
endin

instr 2

prints  "\n---***YOU NOW HEAR THE RESULT OF THIS ANALYZED FILE:***---\n"
ktime line 0, p3, gilen     ; timepointer over the entire sample
asig  pvoc ktime, p4, "Mathews1.pvx", 1 
      outs asig*.6, asig*.6
endin

</CsInstruments>
<CsScore>

i1 0 15.6      ; original sample

i2  17 10   1  ; no change so original sample is played
i2  28 2    1  ; played faster

i2  31 30   1  ; slowed down, same pitch &
i2  63 10   .6 ; sped up and lower pitch

e
</CsScore>
</CsoundSynthesizer>

@tjingboem
Copy link
Member Author

filelen

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
; For Non-realtime ouput leave only the line below:
;-o filelen.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; by Menno Knevel 2022

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1 ; choose between mono or stereo file

ilen   filelen p4	      ; calculate length of soundfile
prints "\nlenght of sample = %2.3f seconds\n\n", ilen
ichn filenchnls  p4	      ; check number of channels

if (ichn == 1) then           ; mono signal
     asig diskin2 p4, 1	
     outs    asig, asig
else
     aL, aR diskin2 p4, 1     ; stereo signal 
     outs    aL, aR
endif
endin

</CsInstruments>
<CsScore>

i 1 0 8 "Mathews.wav"	; mono signal
i 1 8 4 "drumsSlp.wav"	; stereo signal
e
</CsScore>
</CsoundSynthesizer>

@tjingboem
Copy link
Member Author

gen20

<CsoundSynthesizer> 
<CsOptions> 
; Select audio/midi flags here according to platform 
-odac     ;;;realtime audio out 
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too 
; For Non-realtime ouput leave only the line below: 
; -o gen20.wav -W ;;; for file output any platform 
</CsOptions> 
<CsInstruments> 

sr = 44100 
ksmps = 32 
nchnls = 2 
0dbfs  = 1 

instr 1 

insnd   = 10 				;"marimba.aif"
ibasfrq = 44100 / ftlen(insnd)		;use original sample rate of insnd file 

kamp   expseg .001, p3/2, .7, p3/2, .8	;envelope
kpitch line ibasfrq, p3, ibasfrq * .8 
kdens  line 600, p3, 10 
kaoff  line 0, p3, .1
kpoff  line 0, p3, ibasfrq * .5 
kgdur  line .04, p3, .001		;shorten duration of grain during note
imaxgdur =  .5 
igfn = p4 				;different windows
asigL  grain kamp, kpitch, kdens, kaoff, kpoff, kgdur, insnd, igfn, imaxgdur, 0.0 
asigR  grain kamp, kpitch, kdens, kaoff, kpoff, kgdur, insnd, igfn, imaxgdur, 0.0 
       outs asigL, asigR

endin 
</CsInstruments> 
<CsScore> 
f1  0 512  20 2		;Hanning window 
f2  0 512  20 6 1	;Gaussian window 
f10 0 16384 1 "marimba.aif" 0 0 0 

i1 0 5 1		;use Hanning window 
i1 + 5 2		;use Gaussian window
e 
</CsScore> 
</CsoundSynthesizer>

@tjingboem
Copy link
Member Author

delay

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o delay.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr     = 44100
ksmps  = 32
nchnls = 2
0dbfs  = 1

instr    1

adel	init 0
ilev    = p4				;level of direct sound
idelay  = p5 *.001			;Delay in ms
ifd	= p6				;feedback

ain	diskin2 "Mathews.wav", 1, 1
adel	delay   ain + (adel*ifd), idelay;ifd = amount of feedback
asig	moogvcf	adel, 1500, .6, 1	;color feedback
	outs    asig*ilev, ain

endin

</CsInstruments>
<CsScore>
;Delay is in ms
i 1  0  5  1.5  200 .95	;with feedback
i 1  +  5  1.5  20  .95
i 1  +  3  1.5  5   .95
i 1  +  7  2    5    0	;no feedback

e
</CsScore>
</CsoundSynthesizer>

@tjingboem
Copy link
Member Author

exciter

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;real-time audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o exciter.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr=44100
ksmps=32
nchnls=2
0dbfs =1

; by Menno Knevel 2023

instr 1 ; excited sound + original sound

a1 diskin2 "Mathews.wav", 1, 3.5
a2 exciter a1, 3000, 20000, 10, 10	;generate uneven harmonics at maximum setting
     outs a2+a1, a2+a1
endin

instr 2 ; original sound for comparison

a1 diskin2 "Mathews.wav", 1, 3.5
   outs a1, a1
endin

instr 3 ; the effect of the excited sound only

a1 diskin2 "Mathews.wav", 1, 3.5
a2 exciter a1, 3000, 20000, 10, 10	;generate uneven harmonics at maximum setting
   outs a2, a2
endin

</CsInstruments>
<CsScore>
i1 0 5
i2 5 5
i3 10 4.5
e
</CsScore>
</CsoundSynthesizer>

@csounder
Copy link

csounder commented Jun 13, 2024 via email

@tjingboem
Copy link
Member Author

good that you mention this; i forgot all about this.
will add these examples soon....

@csounder
Copy link

csounder commented Jun 13, 2024 via email

@tjingboem
Copy link
Member Author

these examples are now added

@tjingboem tjingboem changed the title replace bad and add good samples part 2: (sometimes) fox replace some samples part 2: (sometimes) fox Jun 23, 2024
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
Assignees

@tjingboem tjingboem

Labels
None yet
Projects
None yet
Milestone
No milestone
Development

No branches or pull requests
2 participants
@csounder @tjingboem