jdk.gradle

enum TargetOS {

    WINDOWS_AMD64( 'windows-x64','windows-amd64', 'zip', '' ),
    LINUX_AMD64( 'linux-x64','linux-amd64', 'tar.gz', '' ),
    LINUX_ARM64( 'linux-aarch64','linux-aarch64', 'tar.gz', '' ),
    MAC_AMD64( 'macos-x64','darwin-amd64', 'tar.gz', 'Contents/Home' ),
    MAC_ARM64( 'macos-aarch64','darwin-aarch64', 'tar.gz', 'Contents/Home'  ),
    GENERIC( null, null, null, null )

    String downloadPlatform

    String downloadExt

    String archiveJavaHome

    String graalvmVersion = '23.1.3'

    String vmDownloadPlatform

    String jdkVersion = '21.0.3'

    TargetOS( String vmDownloadPlatform, String downloadPlatform, String downloadExt, String archiveJavaHome )
    {
        this.vmDownloadPlatform = vmDownloadPlatform
        this.downloadPlatform = downloadPlatform
        this.downloadExt = downloadExt
        this.archiveJavaHome = archiveJavaHome
        this.graalvmVersion = graalvmVersion
    }

    String toJdkPackageName()
    {
        return "graalvm-jdk-${jdkVersion}_${vmDownloadPlatform}_bin"
    }

    String toJdkPackageFile()
    {
        def jdkPackageName = toJdkPackageName()
        return "${jdkPackageName}.${downloadExt}"
    }


    String toDownloadString()
    {
        def jdkPackageFile = toJdkPackageFile()
        return "https://download.oracle.com/graalvm/21/archive/${jdkPackageFile}"
    }

    static from( String targetPlatform )
    {
        if ( targetPlatform == 'windows' )
        {
            return WINDOWS_AMD64
        }
        else if ( targetPlatform == 'linux' )
        {
            return LINUX_AMD64
        }
        else if ( targetPlatform == 'linux-arm64' )
        {
            return LINUX_ARM64
        }
        else if ( targetPlatform == 'mac' )
        {
            return MAC_AMD64
        }
        else if ( targetPlatform == 'mac-arm64' )
        {
            return MAC_ARM64
        }
        else if ( targetPlatform == 'generic' )
        {
            return GENERIC
        }
        else
        {
            throw new GradleException( 'Build target platform not supported: ' + targetPlatform )
        }
    }
}

def getTargetOS()
{
    if ( ext.targetOS != null )
    {
        return ext.targetOS
    }
    ext.targetOS = TargetOS.from( getTargetOsName() )
    return ext.targetOS
}

def getJdkPackageFile()
{
    return isGenericBuild() ? null : getTargetOS().toJdkPackageFile()
}


def getJdkPackageName()
{
    return isGenericBuild() ? null : getTargetOS().toJdkPackageName()
}

def getJdkDownloadUrl()
{
    return isGenericBuild() ? null : getTargetOS().toDownloadString()
}

def isGenericBuild()
{
    return getTargetOS() == TargetOS.GENERIC
}

def getArchiveJavaHome()
{
    return getTargetOS().archiveJavaHome
}

def isSdkBuild()
{
    return getTargetTypeName() == 'sdk'
}

def withDistTar()
{
    return ['linux', 'linux-arm64', 'mac', 'mac-arm64', 'generic'].contains( getTargetOsName() )
}

def withDistZip()
{
    return ['windows', 'generic'].contains( getTargetOsName() )
}

def withJava()
{
    return !isGenericBuild()
}

def isArm64() {
    return [ 'linux-arm64', 'mac-arm64'].contains( getTargetOsName() )
}

def getTargetOsName()
{
    return project.findProperty( 'os' ) ?: 'generic'
}

def getTargetTypeName()
{
    return project.findProperty( 'type' ) ?: 'server'
}

def getTargetBaseName()
{
    return 'enonic-xp-' + getTargetOsName() + ( isGenericBuild() ? '' : '-' + getTargetTypeName() )
}

ext {
    targetOS = null
    targetType = null
    jdkPackageFile = null
    getJdkPackageFile = this.&getJdkPackageFile
    getJdkPackageName = this.&getJdkPackageName
    getJdkDownloadUrl = this.&getJdkDownloadUrl
    getArchiveJavaHome = this.&getArchiveJavaHome
    isGenericBuild = this.&isGenericBuild
    isSdkBuild = this.&isSdkBuild
    getTargetBaseName = this.&getTargetBaseName
    getTargetTypeName = this.&getTargetTypeName
    withDistTar = this.&withDistTar
    withDistZip = this.&withDistZip
    withJava = this.&withJava
    isArm64 = this.&isArm64
}