build.gradle

buildscript {
    repositories {
        maven { url "https://repository.exoplatform.org/public/" }
        mavenCentral()
        google()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:8.3.2'
        classpath 'com.google.gms:google-services:4.4.1'
    }
}

allprojects {
    buildscript {
        repositories {
            maven { url "https://repository.exoplatform.org/public/" }
        }
    }
    repositories {
        maven { url "https://repository.exoplatform.org/public/" }
        mavenLocal()
        google()
    }

    afterEvaluate { project ->
        // Load signing configuration
        def configName = 'release'

        if (project.hasProperty("android") && android.signingConfigs.hasProperty(configName)) {
            def propsFileEnv = System.getenv('GOOGLE_PLAY_EXO_KEYSTORE_PROPS')
            if (propsFileEnv != null){
                def propsFile = file(propsFileEnv)
                if (propsFile.exists()) {
                    println "Loading signing config for $project from " + propsFile
                    def props = new Properties()
                    props.load(new FileInputStream(propsFile))
                    android.signingConfigs[configName].storeFile = file(props['storeFile'])
                    android.signingConfigs[configName].storePassword = props['storePassword']
                    android.signingConfigs[configName].keyAlias = props['keyAlias']
                    android.signingConfigs[configName].keyPassword = props['keyPassword']
                } else {
                    println "The property file referenced by GOOGLE_PLAY_EXO_KEYSTORE_PROPS environment variable doesn't exists or is not readable !"
                        +" no signing configuration for release will be configured. (GOOGLE_PLAY_EXO_KEYSTORE_PROPS: "+propsFileEnv+")"
                }
            } else {
                println "GOOGLE_PLAY_EXO_KEYSTORE_PROPS environment variable doesn't exists ! no signing configuration for release will be configured."
            }
        }
    }
}

tasks.register('clean', Delete) {
    delete rootProject.layout.buildDirectory
}

// This block encapsulate custom properties and make them available to all modules in the project.
ext {
    minSdkVersion = 30 // Android 11
    compileSdkVersion = 34 // Android 14
}