build.gradle

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'pmd'
apply plugin: 'findbugs'
apply plugin: 'checkstyle'
apply plugin: 'cobertura'
apply plugin: 'coveralls'

description = 'Java Chess Protocol Interface'

group = 'com.fluxchess'
version = '1.4.0'
ext.releaseBranch = '1.4.x'

if (!project.hasProperty('buildNumber') || !(project.hasProperty('branchName') && branchName == releaseBranch)) {
  // We're probably building on a dev machine or we're building a branch
  ext.buildNumber = 'dev'
}
if (!project.hasProperty('revisionNumber')) {
  // We're probably building on a dev machine
  ext.revisionNumber = 'dev'
}

if (!version.contains('-') && !(project.hasProperty('releaseVersion') && releaseVersion == version)) {
  // Append '-rc' if we're not releasing yet
  version += '-rc'
}

if (version.contains('-')) {
  // Append the buildNumber if we're not releasing
  version += '.' + buildNumber
}

if (version.contains('-') && !(project.hasProperty('branchName') && branchName == releaseBranch)) {
  // Append the revisionNumber if we're not releasing and not on a release branch
  version += '+' + revisionNumber
}

afterEvaluate { println "Building ${name} version ${version}" }

if (!project.hasProperty('s3AccessKeyId_password')) {
  ext.s3AccessKeyId_password = 'n/a'
}

if (!project.hasProperty('s3SecretAccessKey_password')) {
  ext.s3SecretAccessKey_password = 'n/a'
}

buildscript {
  repositories {
    mavenCentral()
  }

  dependencies {
    classpath 'net.saliman:gradle-cobertura-plugin:2.0.0'
    classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:0.1.6'
  }
}

repositories {
  mavenCentral()
}

tasks.withType(Pmd) {
  pmd {
    ignoreFailures = true
  }
}

tasks.withType(FindBugs) {
  findbugs {
    ignoreFailures = true
  }
}

tasks.withType(Checkstyle) {
  checkstyle {
    configFile = new File("${rootDir}/config/checkstyle/checkstyle.xml")
    ignoreFailures = true
    showViolations = false
  }
}

cobertura.coverageFormats = ['html', 'xml']

sourceSets {
  integration
  testing
}

configurations {
  integrationCompile.extendsFrom testCompile
  integrationRuntime.extendsFrom testRuntime

  testingCompile.extendsFrom testCompile
  testingRuntime.extendsFrom testRuntime
}

dependencies {
  testCompile 'junit:junit:4.+'
  testCompile 'org.slf4j:slf4j-api:1.7.+'
  testCompile 'org.slf4j:slf4j-log4j12:1.7.+'
  testCompile 'log4j:log4j:1.2.+'

  integrationCompile project(path: ':', configuration: 'testRuntime')

  testingCompile project(path: ':', configuration: 'testRuntime')
}

sourceCompatibility = 1.6
targetCompatibility = 1.6

processResources {
  filter(org.apache.tools.ant.filters.ReplaceTokens, tokens: [
    version: project.version,
    buildNumber: project.buildNumber,
    revisionNumber: project.revisionNumber
  ])
}

jar {
  manifest {
    attributes 'Implementation-Title': project.name, 'Implementation-Version': project.version
  }
}

task testsJar(type: Jar, dependsOn: testClasses) {
  classifier = 'tests'
  from sourceSets.test.output
}

task sourcesJar(type: Jar, dependsOn: classes) {
  classifier = 'sources'
  from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
  classifier = 'javadoc'
  from javadoc.destinationDir
}

task integration(type: Test) {
  testClassesDir = sourceSets.integration.output.classesDir
  classpath = sourceSets.integration.runtimeClasspath
}

task dist(type: Zip) {
  def baseDir = "${project.name}-${project.version}"

  into("$baseDir") {
    from 'README.md'
    from 'LICENSE'
    from 'NOTICE'

    from jar
    from sourcesJar
    from javadocJar

    from 'src/dist/engine-interface.txt'
  }
}

artifacts {
  testCompile testsJar

  archives testsJar
  archives sourcesJar
  archives javadocJar
}

uploadArchives {
  if (project.hasProperty('branchName')) {
    if (branchName == releaseBranch) {
      if (version.contains('-')) {
        ext.repositoryName = 'staging'
      } else {
        ext.repositoryName = 'release'
      }

      configurations {
        deployerJars
      }

      dependencies {
        deployerJars 'org.springframework.build:aws-maven:4.+'
      }

      repositories {
        mavenDeployer {
          configuration = configurations.deployerJars
          repository(url: "s3://maven.fluxchess.com/${repositoryName}") {
            authentication(userName: s3AccessKeyId_password, passphrase: s3SecretAccessKey_password)
          }
        }
      }
    } else {
      doLast { println "Skipping upload. Not on ${releaseBranch} branch (${branchName})." }
    }
  } else {
    doLast { println "Skipping upload. No branch name defined." }
  }
}

task wrapper(type: Wrapper) {
  gradleVersion = '1.8'
}