-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathsvitlyna.tal
2321 lines (1926 loc) · 53.4 KB
/
svitlyna.tal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
|00 @System [
&vector $2 &expansion $2 &wst $1 &rst $1
&metadata $2 &r $2 &g $2 &b $2 &debug $1 &state $1
]
|10 @Console [
&vector $2 &read $1
$4
&type $1 &write $1 &error $1
]
|20 @Screen [
&vector $2 &width $2 &height $2 &auto $1
$1
&x $1 &x-l $1 &y $1 &y-l $1 &addr $2 &pixel $1 &sprite $1
]
|80 @Controller [
&vector $2 &button $1 &key $1
]
|90 @Mouse [
&vector $2 &x $2 &y $2 &state $1
$3
&scrollx $2 &scrolly $2
]
|a0 @File [
&vector $2 &success $2 &stat $2 &delete $1
&append $1 &name $2 &length $2 &read $2 &write $2
]
|0000
( color channels )
%Mr { #00 } %Mg { #01 } %Mb { #02 }
@decode-x $2 @decode-y $2
@xfrac $2 @yfrac $2
@img-w $2 @img-h $2 @img-size $4
%Mmax-width { #1000 }
%Mmax-height { #1000 }
%Mmax-name-length { #07ff }
( 8-bit linear RGB colors, used for most processing )
( display device palette is in sRGB )
@color0 [ &r $1 &g $1 &b $1 ]
@color1 [ &r $1 &g $1 &b $1 ]
@color2 [ &r $1 &g $1 &b $1 ]
@color3 [ &r $1 &g $1 &b $1 ]
( extra 4 colors, only used with uxn38 )
@color4 [ &r $1 &g $1 &b $1 ]
@color5 [ &r $1 &g $1 &b $1 ]
@color6 [ &r $1 &g $1 &b $1 ]
@color7 [ &r $1 &g $1 &b $1 ]
@color-min [ &r $1 &g $1 &b $1 ]
@color-max [ &r $1 &g $1 &b $1 ]
( based on @palettes/kwgb )
( k w g b (m=unused) r c y )
%Muxn38-r { #05 }
%Muxn38-g { #02 }
%Muxn38-b { #03 }
%Muxn38-w { #01 }
%Muxn38-c { #06 }
%Muxn38-m { #04 }
%Muxn38-y { #07 }
%Muxn38-k { #00 }
%Mfile-buffer-length { #4000 }
@part-split-step $1
@current-palette $2
@current-mode $1
%Mmode-streaming { #01 }
%Mmode-no-dithering { #02 }
%Mmode-partition-color-func { #04 }
@mode-uxn38 $1
%Mcout { .Console/write DEO }
%Mendl { #0a Mcout }
%Mprint-short { SWP print-byte print-byte }
%Mdebug-byte { Mcout DUP print-byte }
%Mdebug-short { Mcout OVR print-byte DUP print-byte }
%Mdebug32 { Mcout OVR2 Mprint-short DUP2 Mprint-short }
%Mdebug-rgb {
Mcout LIT "# Mcout
ROT DUP print-byte
ROT DUP print-byte
ROT DUP print-byte
}
%Mprint-bgr {
LIT "# Mcout
print-byte print-byte print-byte
}
%Mprint-rgb {
LIT "# Mcout
ROT print-byte SWP print-byte print-byte
}
( common pattern for adding offset to pointer )
%Msk+ { STH2kr ADD2 }
%Ms+ { STH2r ADD2 }
%Mload32 { LDA2k SWP2 INC2 INC2 LDA2 }
%Mnon-zero2 { ORA }
|0100
( init )
( memory check )
;str/memory-check print-str
;end Mprint-short
#1234 ;end STA2
;end LDA2 #1234 EQU2 ?{ ;str/memory-error !fail-str }
LIT 20 Mcout LIT "O Mcout LIT "K Mcout Mendl
;str/init print-str
;on-controller-input .Controller/vector DEO2
( ;on-mouse .Mouse/vector DEO2 )
;ext-uxn38-fg-color .System/expansion DEO2
;ext-uxn38-fg-color/v LDA
DUP #02 LTH ?{ ;str/unexpected-ext !fail-str }
.mode-uxn38 STZ
.Console/type DEI ?{
;read-stdin .Console/vector DEO2
.mode-uxn38 LDZ ?{
;palettes/bw .current-palette STZ2
prepare-palette-builtin
!&palette-chosen
}
;palettes/kwgb .current-palette STZ2
prepare-palette-uxn38
&palette-chosen
Mmode-streaming .current-mode STZ
;str/read print-str ;str/read-stdin print-str
;detect-magic set-on-bytes-received
#0008 set-bytes-expected
;display set-on-pixel-received
!display-init
}
;read-argument .Console/vector DEO2
BRK
( Excerpt from uxn11 documentation:
This describes the nonstandard "03 extensions" command )
( The parts of the command are:
* Command code: Always 0x03.
* Device number: A command that does not load or override a device into a
device slot is zero, otherwise it is a nonzero multiple of sixteen. Some
extensions and some implementations may have further restrictions. If this
number is not a multiple of sixteen (but must be at least sixteen), then
the low nybble indicates how many additional consecutive devices to be
affected; e.g. #33 means to affect all four audio devices (the high nybble
is 3 for the first audio device, and the low nybble 3 means the other 3).
* UUID: Sixteen bytes, which identifies the extension.
* Version: One byte. The emulator writes a nonzero value here (the specific
value is defined by the extension) if it is supported in this mode with
this device number and other parameters, or zero if it is not implemented.
(The uxn program should put zero here by default, so that if running on an
emulator that doesn't process the 03 command at all, it will work.)
* Extra data: The number of bytes and meaning is defined by the specific
extension; this may be read-only, write-only, or some combination. If the
extension is not implemented, then the emulator MUST ignore it and MUST NOT
attempt to write anything here, and MUST NOT override any devices.
An example of how to use this:
@load-ext1 ;ext1 #02 DEO2 ;ext1/v LDA JMP2r
@ext1 03 d0 <uuid> &v 00
This example does not use any extra data, and selects an extension for
device #d0. The <uuid> must be replaced by the appropriate sixteen-byte
UUID for the extension being selected. )
( Allows setting separate foreground and background colours. The device
number must be zero, and the version will be 1. The data is eight 16-bit
numbers, for the colours in order background 0 to 3 and then foreground 0
to 3 (although note that foreground 0 is not normally meaningful), with the
high to low nybble of each being red, green, blue, unused (zero). What
happens if you then try to change colours using the colour ports after
doing this, is not specified. )
@ext-uxn38-fg-color [
03 00
8017 5132 e263 11ed b8c9 0026 1874 5416
&v 00
( k w g b (m=unused) r c y )
0000 fff0 0f00 00f0 f0f0 f000 0ff0 ff00
]
@read-stdin ( -> )
[ LIT2 &index 0000 ]
DUP2 ;file-buf ADD2
.Console/read DEI ROT ROT STA
INC2 DUP2 [ LIT2 &bytes-expected $2 ] NEQ2 ?{
( call subroutine )
;file-buf [ LIT2 &on-bytes-received $2 ] JSR2
POP2 #0000 [ ,&index STR2 ]
BRK
}
[ ,&index STR2 ]
BRK
@read-argument ( -> )
.Console/type DEI
DUP #03 NEQ ?{
;str/usage !fail-str
}
#02 EQU ?{
#00 [ ,&name-length LDR2 ] ;filename ADD2 STA
Mendl
.mode-uxn38 LDZ ?{
;palettes/detected-from-img .current-palette STZ2
!palette-split-init
}
;palettes/kwgb .current-palette STZ2
prepare-palette-uxn38
!display-init
}
.Console/read DEI
[ ,&name-length LDR2 ] ;filename ADD2 STA
[ ,&name-length LDR2 ] INC2
DUP2 Mmax-name-length LTH2 ?{
;str/filename-big !fail-str
}
[ ,&name-length STR2 ]
BRK
&name-length 0000
@read-file ( -> )
;str/read print-str ;str/read-file print-str
;filename print-str Mendl
;detect-magic set-on-bytes-received
#0008 set-bytes-expected
;filename .File/name DEO2
Mfile-buffer-length .File/length DEO2
;file-buf ;read-buffer/window STA2
;read-buffer .Screen/vector DEO2
BRK
@read-buffer ( -> )
;file-buf
DUP2 .File/read DEO2
.File/success DEI2 ADD2 [ ,&window-end STR2 ]
&loop
[ LIT2 &window =file-buf ]
DUP2 [ LIT2 &bytes-expected $2 ] ADD2 ( next window )
[ LIT2 &window-end =file-buf/end ]
GTH2k ?{
POP2
[ ,&window STR2 ]
[ LIT2 &on-bytes-received $2 ] JSR2
!&loop
( copy cmd )
&cmd [
01 0020 0000 =file-buf/pre-end
0000 =file-buf-pre
]
}
( not enough bytes )
;file-buf/end NEQ2 ?{
( buffer full )
( copy last 20 bytes to pre-buffer )
;&cmd .System/expansion DEO2
POP2
Mfile-buffer-length SUB2 [ ,&window STR2 ]
( a good time to take a break? )
[ LIT &break-counter 00 ] INC
DUP #10 NEQ ?{
POP #00 [ ,&break-counter STR ]
BRK
}
[ ,&break-counter STR ]
!read-buffer
}
#0000 .Screen/vector DEO2
[ LIT2 &on-file-end $2 ] JMP2
@set-on-bytes-received ( {routine}* -- )
DUP2 ;read-buffer/on-bytes-received STA2
;read-stdin/on-bytes-received STA2
JMP2r
@set-bytes-expected ( bytes* -- )
DUP2 ;read-buffer/bytes-expected STA2
;read-stdin/bytes-expected STA2
JMP2r
@set-on-pixel-received ( bytes* -- )
DUP2 ;ff-next-pixel/on-pixel-received STA2
;qoi-on-pixel-received/routine STA2
JMP2r
@set-on-file-end ( bytes* -- )
;read-buffer/on-file-end STA2
JMP2r
( ui )
@on-controller-input ( -> )
.Controller/button DEI
DUP #01 AND ?on-a-ctrl
DUP #02 AND ?on-b-alt
DUP #10 AND ?on-dpad-up
#20 AND ?on-dpad-down
BRK
@on-a-ctrl ( -> )
Mmode-streaming is-mode ?end
[ LIT2 00 -mode-uxn38 ] STZ
;palettes/detected-from-img .current-palette STZ2
.part-split-step LDZ [ #03 ] EQU ?{
!palette-split-init
}
prepare-palette-avg
!display-init
@on-b-alt ( -> )
Mmode-streaming is-mode ?end
.current-palette LDZ2 ;palettes/detected-from-img NEQ2 ?{
Mmode-partition-color-func is-mode ?{
Mmode-partition-color-func #01 set-mode
!display-init
}
Mmode-partition-color-func #00 set-mode
( also toggle dithering, allowing 4 modes )
}
Mmode-no-dithering is-mode ?{
Mmode-no-dithering #01 set-mode
!display-init
}
Mmode-no-dithering #00 set-mode
!display-init
@on-dpad-up ( -> )
Mmode-streaming is-mode ?end
.current-palette LDZ2
#000c ADD2
DUP2 ;palettes/kwgb NEQ2 ?{
;ext-uxn38-fg-color/v LDA #01 NEQ ?{
[ LIT2 01 -mode-uxn38 ] STZ
.current-palette STZ2
prepare-palette-uxn38
!display-init
}
}
[ LIT2 00 -mode-uxn38 ] STZ
DUP2 ;palettes/detected-from-img LTH2 ?{
POP2 ;palettes
}
.current-palette STZ2
prepare-palette-builtin
!display-init
@on-dpad-down ( -> )
Mmode-streaming is-mode ?end
.current-palette LDZ2
DUP2 ;palettes GTH2 ?{
POP2 ;palettes/detected-from-img
}
#000c SUB2
DUP2 ;palettes/kwgb NEQ2 ?{
;ext-uxn38-fg-color/v LDA #01 NEQ ?{
[ LIT2 01 -mode-uxn38 ] STZ
.current-palette STZ2
prepare-palette-uxn38
!display-init
}
}
[ LIT2 00 -mode-uxn38 ] STZ
.current-palette STZ2
prepare-palette-builtin
!display-init
@is-mode ( mode -: bool )
.current-mode LDZ AND #00 NEQ
JMP2r
@set-mode ( mode value -- bool )
?{ .current-mode LDZ EOR .current-mode STZ JMP2r }
.current-mode LDZ ORA .current-mode STZ
JMP2r
( image formats )
@detect-magic ( {buffer}* -- )
DUP2 ;&farbfeld str-starts-with ?{
!&try-qoi
}
;&farbfeld print-str Mendl
POP2
;ff-size set-on-bytes-received
#0008 set-bytes-expected
JMP2r
[ &farbfeld "farbfeld 00 ]
[ &qoif "qoif 00 ]
&try-qoi
DUP2 ;&qoif str-starts-with ?{
!bad-file
}
;&qoif print-str Mendl
!qoi-header1
@ff-size ( {buffer}* -- )
LDA2k Mnon-zero2 ?too-large
INC2 INC2 LDA2k ( width ) SWP2
INC2 INC2 LDA2k Mnon-zero2 ?too-large
INC2 INC2 LDA2 ( height )
handle-image-size
;ff-next-pixel set-on-bytes-received
#0008 set-bytes-expected
JMP2r
( farbfeld uses 16-bit depth, not alpha-premultiplied )
( we don't load the lower 8 bits )
@ff-next-pixel ( {buffer}* -- )
STH2k #0006 ADD2 LDA ( alpha )
( 255 INC becomes 0, so lambda isn't skipped -> opaque )
INCk ?{
( alpha is zero )
POP
LDAkr STHr ( r )
#0002 Msk+ LDA ( g )
#0004 Ms+ LDA ( b )
!&result
}
#00 SWP
DUP2 #00 LDAkr STHr MUL2 POP ( 00 aa ar )
ROT ROT
DUP2 #00 #0002 Msk+ LDA MUL2 POP ( ar 00 aa ag )
ROT ROT
#00 #0004 Ms+ LDA MUL2 POP ( ar ag ab )
&result
srgb-to-linear
[ LIT2 &on-pixel-received $2 ] JMP2
@alpha-multiply ( r g b a -- r*a g*a b*a )
INCk ?{ POP JMP2r } ( don't multiply if opaque )
( r g b a )
STHk #00 ROT #00 STHr MUL2 POP STH
( r g a | b*a )
STHk #00 ROT #00 STHr MUL2 POP STH
( r a | b*a g*a )
STH #00 SWP #00 STHr MUL2 POP
STH2r SWP2r
JMP2r
@qoi-header1 ( {buffer}* -- )
#0004 ADD2
( width )
DUP2 LDA2 Mnon-zero2 ?too-large
INC2 INC2 LDA2 ;&w STA2
;qoi-header2 set-on-bytes-received
#0006 set-bytes-expected
JMP2r
&w $2
@qoi-header2 ( {buffer}* -- )
( height )
LDA2k Mnon-zero2 ?too-large
INC2 INC2 LDA2k
( width, again )
;qoi-header1/w LDA2
SWP2 handle-image-size
INC2 INC2 INC2 ( ignore channel count )
LDA
LIT "S Mdebug-byte Mendl
;qoi-is-linear STA
;qoi-last
&loop
#0000 OVR2 STA2
INC2 INC2
DUP2 ;qoi-index/end LTH2
?&loop
POP2
#ff ;qoi-last/a STA
;qoi-chunk set-on-bytes-received
#0001 set-bytes-expected
JMP2r
@qoi-last [ &r $1 &g $1 &b $1 &a $1 ]
@qoi-index [ &r $40 &g $40 &b $40 &a $40 ] &end $2
%Mqoi-stlast {
STH2 DUP2 ;qoi-last/r STA2
STH2r DUP2 ;qoi-last/b STA2
}
@qoi-stindex ( r g b a -- r g b a )
SWP2k
( r g b a b a r g )
#05 MUL ( 5g )
SWP #03 MUL ADD ( 3r )
SWP #0b MUL ADD ( 11a )
SWP #07 MUL ADD ( 7b )
#3f AND LITr 00 STH
SWP2k
;qoi-index/g Msk+ STA
;qoi-index/r Msk+ STA
;qoi-index/a Msk+ STA
;qoi-index/b Ms+ STA
JMP2r
@qoi-chunk ( {buffer}* -- )
LDA
( QOI_OP_RGB )
#fe NEQk ?{
POP2
;qoi-chunk-rgb set-on-bytes-received
#0003 set-bytes-expected
JMP2r
}
POP
( QOI_OP_RGBA )
#ff NEQk ?{
POP2
;qoi-chunk-rgba set-on-bytes-received
#0004 set-bytes-expected
JMP2r
}
POP
( QOI_OP_INDEX )
DUP #06 SFT ?{
( 7 6 5 4 3 2 1 0 )
( 0 0| index )
#00 SWP #3f AND STH2
;qoi-index/r Msk+ LDA
;qoi-index/g Msk+ LDA
;qoi-index/b Msk+ LDA
;qoi-index/a Ms+ LDA
Mqoi-stlast
alpha-multiply
!qoi-on-pixel-received
}
( QOI_OP_DIFF )
DUP #06 SFT #01 NEQ ?{
( 7 6 5 4 3 2 1 0 )
( 0 1| dr| dg| db )
DUP #04 SFT #03 AND ;qoi-last/r LDA ADD #02 SUB
OVR #02 SFT #03 AND ;qoi-last/g LDA ADD #02 SUB
ROT #03 AND ;qoi-last/b LDA ADD #02 SUB
;qoi-last/a LDA
Mqoi-stlast
qoi-stindex
alpha-multiply
!qoi-on-pixel-received
}
( QOI_OP_LUMA )
DUP #06 SFT #02 NEQ ?{
( 7 6 5 4 3 2 1 0 | 7 6 5 4 3 2 1 0 )
( 1 0| diff green | dr-rg | db-dg )
#3f AND ;qoi-chunk-luma/dg STA
;qoi-chunk-luma set-on-bytes-received
#0001 set-bytes-expected
JMP2r
}
( QOI_OP_RUN )
( 7 6 5 4 3 2 1 0 )
( 1 1| run length )
#3f AND INC
;qoi-last/r LDA
;qoi-last/g LDA
;qoi-last/b LDA
;qoi-last/a LDA
alpha-multiply
ROT STH STH2
#00
( wst: length count | rst: r g b )
&run-loop
ROTkr STHr STH2r
( wst: length count r g b | rst: r g b )
qoi-on-pixel-received
INC
NEQk
?&run-loop
POP2 POP2r POPr
JMP2r
@qoi-chunk-rgb ( {buffer}* -- )
LDAk
ROT ROT INC2 LDAk
ROT ROT INC2 LDA
;qoi-last/a LDA
qoi-stindex
Mqoi-stlast
alpha-multiply
qoi-on-pixel-received
;qoi-chunk set-on-bytes-received
#0001 set-bytes-expected
JMP2r
@qoi-chunk-rgba ( {buffer}* -- )
LDAk
ROT ROT INC2 LDAk
ROT ROT INC2 LDAk
ROT ROT INC2 LDA
qoi-stindex
Mqoi-stlast
alpha-multiply
qoi-on-pixel-received
;qoi-chunk set-on-bytes-received
#0001 set-bytes-expected
JMP2r
( 7 6 5 4 3 2 1 0 | 7 6 5 4 3 2 1 0 )
( 0 1| diff green | dr-rg | db-dg )
@qoi-chunk-luma ( {buffer}* -- )
LDA
DUP #04 SFT
[ ;&dg LDA ] ADD #28 SUB
;qoi-last/r LDA ADD
[ ;&dg LDA ] #20 SUB
;qoi-last/g LDA ADD
ROT #0f AND
[ ;&dg LDA ] ADD #28 SUB
;qoi-last/b LDA ADD
;qoi-last/a LDA
qoi-stindex
Mqoi-stlast
alpha-multiply
qoi-on-pixel-received
;qoi-chunk set-on-bytes-received
#0001 set-bytes-expected
JMP2r
&dg $1
@qoi-on-pixel-received ( r g b -- )
[ ,qoi-is-linear LDR ] ?{
srgb-to-linear
}
[ LIT2 &routine $2 ] JMP2
@qoi-is-linear $1
( misc. )
@handle-image-size ( w* h* -- )
;str/height print-str DUP2 Mprint-short Mendl
DUP2 .Screen/height DEO2 .img-h STZ2
;str/width print-str DUP2 Mprint-short Mendl
DUP2 .Screen/width DEO2 .img-w STZ2
JMP2r
@prepare-palette-colors-builtin ( -- )
.current-palette LDZ2
LDA2k .color0/g STZ .color0/r STZ
INC2 INC2 LDA2k .color1/r STZ .color0/b STZ
INC2 INC2 LDA2k .color1/b STZ .color1/g STZ
INC2 INC2 LDA2k .color2/g STZ .color2/r STZ
INC2 INC2 LDA2k .color3/r STZ .color2/b STZ
INC2 INC2 LDA2 .color3/b STZ .color3/g STZ
JMP2r
@prepare-palette-builtin ( -- )
prepare-palette-colors-builtin
( fallthrough )
@prepare-palette-screen ( -- )
{ 20 "0123 0a 00 } STH2r print-str
.color0/r LDZ linear-to-srgb-single #f0 AND
.color1/r LDZ linear-to-srgb-single #04 SFT ORA
.color2/r LDZ linear-to-srgb-single #f0 AND
.color3/r LDZ linear-to-srgb-single #04 SFT ORA
LIT "R Mdebug-short Mendl
.System/r DEO2
.color0/g LDZ linear-to-srgb-single #f0 AND
.color1/g LDZ linear-to-srgb-single #04 SFT ORA
.color2/g LDZ linear-to-srgb-single #f0 AND
.color3/g LDZ linear-to-srgb-single #04 SFT ORA
LIT "G Mdebug-short Mendl
.System/g DEO2
.color0/b LDZ linear-to-srgb-single #f0 AND
.color1/b LDZ linear-to-srgb-single #04 SFT ORA
.color2/b LDZ linear-to-srgb-single #f0 AND
.color3/b LDZ linear-to-srgb-single #04 SFT ORA
LIT "B Mdebug-short Mendl
.System/b DEO2
( get minimum and maximum colors )
.color3/r LDZ [ LITr -color2/r ]
&get-min-r ( min-r | {zaddr} )
STHkr LDZ
LTHk ?{ SWP } POP
STHkr .color0/r EQU ?&get-min-r-end
[ LITr 03 ] SUBr
!&get-min-r
&get-min-r-end
POPr
LIT "r Mdebug-byte Mendl
.color-min/r STZ
.color3/g LDZ [ LITr -color2/g ]
&get-min-g ( min-g | {zaddr} )
STHkr LDZ
LTHk ?{ SWP } POP
STHkr .color0/g EQU ?&get-min-g-end
[ LITr 03 ] SUBr
!&get-min-g
&get-min-g-end
POPr
LIT "g Mdebug-byte Mendl
.color-min/g STZ
.color3/b LDZ [ LITr -color2/b ]
&get-min-b ( min-b | {zaddr} )
STHkr LDZ
LTHk ?{ SWP } POP
STHkr .color0/b EQU ?&get-min-b-end
[ LITr 03 ] SUBr
!&get-min-b
&get-min-b-end
POPr
LIT "b Mdebug-byte Mendl
.color-min/b STZ
.color3/r LDZ [ LITr -color2/r ]
&get-max-r ( max-r | {zaddr} )
STHkr LDZ
GTHk ?{ SWP } POP
STHkr .color0/r EQU ?&get-max-r-end
[ LITr 03 ] SUBr
!&get-max-r
&get-max-r-end
POPr
LIT "R Mdebug-byte Mendl
.color-max/r STZ
.color3/g LDZ [ LITr -color2/g ]
&get-max-g ( max-g | {zaddr} )
STHkr LDZ
GTHk ?{ SWP } POP
STHkr .color0/g EQU ?&get-max-g-end
[ LITr 03 ] SUBr
!&get-max-g
&get-max-g-end
POPr
LIT "G Mdebug-byte Mendl
.color-max/g STZ
.color3/b LDZ [ LITr -color2/b ]
&get-max-b ( max-b | {zaddr} )
STHkr LDZ
GTHk ?{ SWP } POP
STHkr .color0/b EQU ?&get-max-b-end
[ LITr 03 ] SUBr
!&get-max-b
&get-max-b-end
POPr
LIT "B Mdebug-byte Mendl
.color-max/b STZ
JMP2r
@prepare-palette-uxn38 ( -- )
;ext-uxn38-fg-color .System/expansion DEO2
;str/uxn38-color-ext print-str
prepare-palette-colors-builtin
( color4 = magenta(unused): #ff00ff )
LIT2 ff
00 .color4/r STZ2
LIT2 ff
( color5 = red: #ff0000 )
ff .color4/b STZ2
LIT2 00
00 .color5/g STZ2
( color6 = cyan: #00ffff )
LIT2 00
ff .color6/r STZ2
LIT2 ff
( color7 = yellow: #ffff00 )
ff .color6/b STZ2
LIT2 ff
00 .color7/g STZ2
( color-min: #000000 )
LIT2 00
00 .color-min/r STZ2
LIT2 00
( color-max: #ffffff )
ff .color-min/b STZ2
LIT2 ff
ff .color-max/g STZ2
JMP2r
( 6-bit linear RGB is used for dithering )
( 7-bit linear RGB is used for color partitions )
@rgb-sft ( r g b sft -- rs gs bs )
SFTk STH NIP ( r g sft | bs )
SFTk STH NIP ( r sft | bs gs )
SFT ( rs | bs gs )
STHr STHr
JMP2r
( image processing )
( 8-bit sRGB triplet to 8-bit linear RGB triplet )
@srgb-to-linear ( sr sg sb -- r g b )
ROT #00 SWP ;&lut ADD2 LDA
ROT #00 SWP ;&lut ADD2 LDA
ROT #00 SWP ;&lut ADD2 LDA
JMP2r
&lut [
00 00 00 00 00 00 00 01 01 01 01 01 01 01 01 01
01 01 02 02 02 02 02 02 02 02 03 03 03 03 03 03
04 04 04 04 04 05 05 05 05 06 06 06 06 07 07 07
08 08 08 08 09 09 09 0a 0a 0a 0b 0b 0c 0c 0c 0d
0d 0d 0e 0e 0f 0f 10 10 11 11 11 12 12 13 13 14
14 15 16 16 17 17 18 18 19 19 1a 1b 1b 1c 1d 1d
1e 1e 1f 20 20 21 22 23 23 24 25 25 26 27 28 29
29 2a 2b 2c 2d 2d 2e 2f 30 31 32 33 33 34 35 36
37 38 39 3a 3b 3c 3d 3e 3f 40 41 42 43 44 45 46
47 48 49 4a 4c 4d 4e 4f 50 51 52 54 55 56 57 58
5a 5b 5c 5d 5f 60 61 63 64 65 67 68 69 6b 6c 6d
6f 70 72 73 74 76 77 79 7a 7c 7d 7f 80 82 83 85
86 88 8a 8b 8d 8e 90 92 93 95 97 98 9a 9c 9d 9f
a1 a3 a4 a6 a8 aa ab ad af b1 b3 b5 b7 b8 ba bc
be c0 c2 c4 c6 c8 ca cc ce d0 d2 d4 d6 d8 da dc
de e0 e2 e5 e7 e9 eb ed ef f2 f4 f6 f8 fa fd ff
]
( single 8-bit linear RGB value to 8-bit sRGB value )
@linear-to-srgb-single ( scolor -- color )
#00 SWP ;&lut ADD2 LDA
JMP2r
&lut [
00 0d 16 1c 22 26 2a 2e 32 35 38 3b 3d 40 42 45
47 49 4b 4d 4f 51 53 55 56 58 5a 5c 5d 5f 60 62
63 65 66 68 69 6a 6c 6d 6e 70 71 72 73 75 76 77
78 79 7a 7c 7d 7e 7f 80 81 82 83 84 85 86 87 88
89 8a 8b 8c 8d 8e 8f 90 91 92 93 94 94 95 96 97
98 99 9a 9b 9b 9c 9d 9e 9f 9f a0 a1 a2 a3 a3 a4
a5 a6 a7 a7 a8 a9 aa aa ab ac ad ad ae af af b0
b1 b2 b2 b3 b4 b4 b5 b6 b6 b7 b8 b9 b9 ba bb bb
bc bd bd be be bf c0 c0 c1 c2 c2 c3 c4 c4 c5 c5
c6 c7 c7 c8 c8 c9 ca ca cb cb cc cd cd ce ce cf
d0 d0 d1 d1 d2 d2 d3 d4 d4 d5 d5 d6 d6 d7 d7 d8
d8 d9 da da db db dc dc dd dd de de df df e0 e0
e1 e2 e2 e3 e3 e4 e4 e5 e5 e6 e6 e7 e7 e8 e8 e9
e9 ea ea eb eb ec ec ed ed ee ee ee ef ef f0 f0
f1 f1 f2 f2 f3 f3 f4 f4 f5 f5 f6 f6 f6 f7 f7 f8
f8 f9 f9 fa fa fb fb fb fc fc fd fd fe fe ff ff
]
( partitioning color space, via median cut algorithm )
( see bottom of file for partition structure )
%Mpart-sort-buffer-size { #0200 }
%Mpart-sort-buffers-size { #0600 }
%Mpart-size { #060a }
%Mpart-max-color { #7f }
%Mpart-color-sft { #01 }
%Mpart-color-sft-ret { #10 }
@part-debug ( part -- )
( POP JMP2r )
#00 OVR Mpart-size MUL2 STH2
( { "part 20 00 } STH2r print-str DUP print-byte Mcout )
LIT "R Mcout ;part/r-beg Msk+ LDA2
SWP print-byte LIT "- Mcout print-byte LIT ", Mcout
LIT "G Mcout ;part/g-beg Msk+ LDA2
SWP print-byte LIT "- Mcout print-byte LIT ", Mcout
LIT "B Mcout ;part/b-beg Msk+ LDA2
SWP print-byte LIT "- Mcout print-byte Mendl
.part-split-step LDZ INC LTH ?{ POP2r JMP2r }
LIT "C Mcout ;part/count Msk+
LDA2k Mprint-short INC2 INC2 LDA2 Mprint-short Mendl
#0000
LIT "S Mcout LIT "R Mcout Mendl
&loopr
DUP2 #02 SFT2 NIP
print-byte LIT "| Mcout
DUP2 ;part/r-sort Msk+ ADD2 LDA2 Mprint-short
INC2 INC2
DUP2 ;part/r-sort Msk+ ADD2 LDA2 Mprint-short
INC2 INC2
DUP2
DUP #30 SFT ?{ Mendl !&end-print-r }
#20 Mcout
&end-print-r
Mpart-sort-buffer-size NEQ2
?&loopr
POP2 #0000
LIT "S Mcout LIT "G Mcout Mendl
&loopg
DUP2 #02 SFT2 NIP
print-byte LIT "| Mcout
DUP2 ;part/g-sort Msk+ ADD2 LDA2 Mprint-short
INC2 INC2
DUP2 ;part/g-sort Msk+ ADD2 LDA2 Mprint-short
INC2 INC2
DUP2
DUP #30 SFT ?{ Mendl !&end-print-g }
#20 Mcout
&end-print-g
Mpart-sort-buffer-size NEQ2
?&loopg
#0000
LIT "S Mcout LIT "B Mcout Mendl