build.gradle

plugins {
    id 'java'
    id "org.sonarqube" version "5.1.0.4882"
    id 'org.springframework.boot' version '3.3.5'
    id 'io.spring.dependency-management' version '1.1.6'
    id 'jacoco'
}

group = 'com.threestar'
version = '0.0.1-SNAPSHOT'

jacoco {
    toolVersion = '0.8.12'
}

test {
    jacoco {
        destinationFile = layout.buildDirectory.file("jacoco/jacoco.exec").get().asFile
    }

    useJUnitPlatform {
        includeEngines 'junit-jupiter'
    }

    finalizedBy jacocoTestReport
}

jacocoTestReport {
    reports {
        html.required.set(true)
        xml.required.set(true)
        csv.required.set(false)

        html.outputLocation.set(layout.buildDirectory.dir("jacoco/html"))
        xml.outputLocation.set(layout.buildDirectory.file("jacoco/jacoco.xml"))
    }

    // 이 설정을 열어주면 Code Coverage가 일정 이상이어야 Build됨
    // finalizedBy 'jacocoTestCoverageVerification'
}

jacocoTestCoverageVerification {
    violationRules {
        rule {
            limit {
                minimum = 0.30
            }
        }

        rule {
            enabled = true
            element = 'CLASS'

            limit {
                counter = 'BRANCH'
                value = 'COVEREDRATIO'
                minimum = 0.50
            }

            limit {
                counter = 'LINE'
                value = 'COVEREDRATIO'
                minimum = 0.50
            }

            limit {
                counter = 'LINE'
                value = 'TOTALCOUNT'
                maximum = 300
            }

            excludes = [
                    '*.test.*'
            ]
        }
    }
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation("org.springframework.boot:spring-boot-starter-batch")
    implementation 'com.github.gavlyukovskiy:p6spy-spring-boot-starter:1.9.0'
    implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
    implementation 'io.jsonwebtoken:jjwt-jackson:0.11.5'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.5'
    implementation 'org.apache.poi:poi:5.2.3'
    implementation 'org.apache.poi:poi-ooxml:5.2.3'
    implementation "org.testcontainers:localstack:1.16.3"
    implementation "com.amazonaws:aws-java-sdk-s3:1.12.529"
    implementation 'javax.xml.bind:jaxb-api:2.3.1'
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.0.2'
    implementation 'org.springframework.cloud:spring-cloud-starter-aws:2.2.6.RELEASE'
    implementation 'org.springframework.boot:spring-boot-starter-mail'
    implementation 'org.apache.commons:commons-math3:3.6.1'

    implementation 'org.springframework.boot:spring-boot-starter-validation'


    // queryDSL
    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:5.0.0:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.mysql:mysql-connector-j'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.security:spring-security-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'


}

test {
    useJUnitPlatform()
    finalizedBy 'jacocoTestReport'
}

sonarqube {
    properties {
        property "sonar.issue.ignore.multicriteria", "e1,e2"
        property "sonar.issue.ignore.multicriteria.e1.ruleKey", "java:S1134" // TODO 관련 룰
        property "sonar.issue.ignore.multicriteria.e1.resourceKey", "**/*"
        property "sonar.issue.ignore.multicriteria.e2.ruleKey", "java:S1135" // FIXME 관련 룰
        property "sonar.issue.ignore.multicriteria.e2.resourceKey", "**/*"
        property "sonar.scm.disabled", "true"
        property 'sonar.exclusions', '''
            **/test/**, 
            **/resources/**, 
            **/*Application*.java, 
            **/*Controller*.java, 
            **/*Config.java,
            **/*Response.java, 
            **/*Exception.java, 
            **/security/**, 
            **/support/**, 
            **/Q*.java, 
            **/dto/**, 
            **/entity/**, 
            **/model/**, 
            **/repository/**, 
            **/global/exception/**,
            **/scheduler/**,
            **/global/util/**
        '''
    }
}