EXWM always show candidates childframe on one monitor

[drshapeless]

I have a dual monitor setup with EXWM.

I have read the wiki that commit 1c53066 fixed EXWM.

However, after this commit, the completion candidates only show on my left monitor even I am typing on my right monitor.

Before this commit, everything was fine. I am not sure what is causing the issue. I am currently at commit 497c853, one commit before the "exwm fix" commit, everything is back to normal.

I am using the HEAD of Emacs built from source.

[minad]

Hi! Unfortunately I do not know how to improve this and I cannot test EXWM on multiple monitors. Help with this would be welcome. In commit 1c53066, I made sure that the Corfu child frame is always visible, and not occluded by EXWM windows. In #235 there is a potential solution, but it looks a little bit ugly. I think the problem is that under EXWM the frame is decoupled from its parent and as such the relative positioning is computed always to the frame which was first used to create the popup.

[drshapeless]

Yes, you are right, if the frame is decoupled from its parent, the position is always relative to the top left corner of your monitors setup.

With the reference to #235, I quickly draft a solution. Just add the x position when there is a exwm-connection in the set-frame-position function.

(defun corfu--make-frame (frame x y width height buffer)
  "Show BUFFER in child frame at X/Y with WIDTH/HEIGHT.
FRAME is the existing frame."
  (when-let (((frame-live-p frame))
             (timer (frame-parameter frame 'corfu--hide-timer)))
    (cancel-timer timer)
    (set-frame-parameter frame 'corfu--hide-timer nil))
  (let* ((window-min-height 1)
         (window-min-width 1)
         (inhibit-redisplay t)
         (x-gtk-resize-child-frames corfu--gtk-resize-child-frames)
         (before-make-frame-hook)
         (after-make-frame-functions)
         (parent (window-frame)))
    (unless (and (frame-live-p frame)
                 (eq (frame-parent frame)
                     (and (not (bound-and-true-p exwm--connection)) parent))
                 ;; If there is more than one window, `frame-root-window' may
                 ;; return nil.  Recreate the frame in this case.
                 (window-live-p (frame-root-window frame)))
      (when frame (delete-frame frame))
      (setq frame (make-frame
                   `((parent-frame . ,parent)
                     (minibuffer . ,(minibuffer-window parent))
                     (width . 0) (height . 0) (visibility . nil)
                     ,@corfu--frame-parameters))))
    ;; XXX HACK Setting the same frame-parameter/face-background is not a nop.
    ;; Check before applying the setting. Without the check, the frame flickers
    ;; on Mac. We have to apply the face background before adjusting the frame
    ;; parameter, otherwise the border is not updated.
    (let ((new (face-attribute 'corfu-border :background nil 'default)))
      (unless (equal (face-attribute 'internal-border :background frame 'default) new)
        (set-face-background 'internal-border new frame)))
    ;; Reset frame parameters if they changed.  For example `tool-bar-mode'
    ;; overrides the parameter `tool-bar-lines' for every frame, including child
    ;; frames.  The child frame API is a pleasure to work with.  It is full of
    ;; lovely surprises.
    (when-let ((params (frame-parameters frame))
               (reset (seq-remove
                       (lambda (p) (equal (alist-get (car p) params) (cdr p)))
                       `((background-color
                          . ,(face-attribute 'corfu-default :background nil 'default))
                         (font . ,(frame-parameter parent 'font))
                         ,@corfu--frame-parameters))))
      (modify-frame-parameters frame reset))
    (let ((win (frame-root-window frame)))
      (unless (eq (window-buffer win) buffer)
        (set-window-buffer win buffer))
      ;; Disallow selection of root window (gh:minad/corfu#63)
      (set-window-parameter win 'no-delete-other-windows t)
      (set-window-parameter win 'no-other-window t)
      ;; Mark window as dedicated to prevent frame reuse (gh:minad/corfu#60)
      (set-window-dedicated-p win t))
    (redirect-frame-focus frame parent)
    (set-frame-size frame width height t)
    (unless (equal (frame-position frame) (cons x y))
      (if (bound-and-true-p exwm--connection)          
          (set-frame-position
           frame
           (+ x (car (frame-monitor-geometry exwm-workspace--current)))
           (+ y (car (cdr (frame-monitor-geometry exwm-workspace--current)))))
        (set-frame-position frame x y))
      ))
  (make-frame-visible frame)
  ;; Unparent child frame if EXWM is used, otherwise EXWM buffers are drawn on
  ;; top of the Corfu child frame.
  (when (and (bound-and-true-p exwm--connection) (frame-parent frame))
    (set-frame-parameter frame 'parent-frame nil))
  frame)

This is a quick and dirty solution, but it works well. Just check if it is in exwm when setting frame position, add the x y position with the window geometry.

To be clear, this is the only thing I modified.

    (unless (equal (frame-position frame) (cons x y))
      (if (bound-and-true-p exwm--connection)          
          (set-frame-position
           frame
           (+ x (car (frame-monitor-geometry exwm-workspace--current)))
           (+ y (car (cdr (frame-monitor-geometry exwm-workspace--current)))))
        (set-frame-position frame x y))
      )

[jsilve24]

could you provide the function get-focused-monitor-geometry? I am getting an error with the advise function as written

[jsilve24]

Did a bit of digging, found it in your public emacs repo:

  ;; Advise packages that use posframe for a multi-head setup

  (defun get-focused-monitor-geometry ()
    "Get the geometry of the monitor displaying the selected frame in EXWM."
    (let* ((monitor-attrs (frame-monitor-attributes))
           (workarea (assoc 'workarea monitor-attrs))
           (geometry (cdr workarea)))
      (list (nth 0 geometry) ; X
            (nth 1 geometry) ; Y
            (nth 2 geometry) ; Width
            (nth 3 geometry) ; Height
            )))

  (defun advise-corfu-make-frame-with-monitor-awareness (orig-fun frame x y width height buffer)
    "Advise `corfu--make-frame` to be monitor-aware, adjusting X and Y according to the focused monitor."

    ;; Get the geometry of the currently focused monitor
    (let* ((monitor-geometry (get-focused-monitor-geometry))
           (monitor-x (nth 0 monitor-geometry))
           (monitor-y (nth 1 monitor-geometry))
           ;; You may want to adjust the logic below if you have specific preferences
           ;; on where on the monitor the posframe should appear.
           ;; Currently, it places the posframe at its intended X and Y, but ensures
           ;; it's within the bounds of the focused monitor.
           (new-x (+ monitor-x x))
           (new-y (+ monitor-y y)))

      ;; Call the original function with potentially adjusted coordinates
      (funcall orig-fun frame new-x new-y width height buffer)))


  (advice-add 'corfu--make-frame :around #'advise-corfu-make-frame-with-monitor-awareness)

Just started playing with it, but it seems like it works. Thanks!

[chubbymomo]

Sorry for not including that... Hopefully you find it useful!

[LemonBreezes]

Also, in case you want to use Polybar with EXWM, you need to modify the above advice to also offset Corfu based on the Emacs frame position: emacs-exwm/exwm#31.

[chubbymomo]

Oops, you're right. Sorry! I didn't think of that, I don't use a bar with EXWM. Wonder if there's a way to do that dynamically, might look into that.

[jsilve24]

In the past week or so I have started to get an error with this fix.

Debugger entered--Lisp error: (wrong-number-of-arguments ((t) (orig-fun frame x y width height buffer) "Advise `corfu--make-frame` to be monitor-aware, ad..." (let* ((monitor-geometry (get-focused-monitor-geometry)) (monitor-x (nth 0 monitor-geometry)) (monitor-y (nth 1 monitor-geometry)) (new-x (+ monitor-x x)) (new-y (+ monitor-y y))) (funcall orig-fun frame new-x new-y width height buffer))) 6)
  advise-corfu-make-frame-with-monitor-awareness(#<subr corfu--make-frame> nil 109 144 144 126)
  apply(advise-corfu-make-frame-with-monitor-awareness #<subr corfu--make-frame> (nil 109 144 144 126))
  corfu--make-frame(nil 109 144 144 126)
  corfu--popup-show((#<window 194 on zero-inflated-poisson-identifiability.R> 115 (104 . 126) 0 nil 115 (13 . 7) nil (0 . 0) (8 . 18)) 0 18 (#("expand" 0 6 (face orderless-match-face-0)) #("expand_" 0 6 (face orderless-match-face-0)) #("expand.grid" 0 6 (face orderless-match-face-0)) #("expand_grid" 0 6 (face orderless-match-face-0)) #("expand_scale" 0 6 (face orderless-match-face-0)) #("expand_limits" 0 6 (face orderless-match-face-0)) #("expand.model.frame" 0 6 (face orderless-match-face-0))) 0 nil 15)
  corfu--candidates-popup((#<window 194 on zero-inflated-poisson-identifiability.R> 115 (104 . 126) 0 nil 115 (13 . 7) nil (0 . 0) (8 . 18)))
  #f(compiled-function (&optional auto) #<bytecode 0x97b7d2d7ff7da9c>)(auto)
  apply(#f(compiled-function (&optional auto) #<bytecode 0x97b7d2d7ff7da9c>) auto)
  #f(compiled-function (&rest args) #<bytecode -0x11808fa36a2b0be5>)(auto)
  apply(#f(compiled-function (&rest args) #<bytecode -0x11808fa36a2b0be5>) auto)
  corfu--exhibit(auto)
  corfu--auto-complete-deferred((#<window 194 on zero-inflated-poisson-identifiability.R> #<buffer zero-inflated-poisson-identifiability.R> 3918 121))
  apply(corfu--auto-complete-deferred (#<window 194 on zero-inflated-poisson-identifiability.R> #<buffer zero-inflated-poisson-identifiability.R> 3918 121))
  timer-event-handler([t 26414 25656 693690 nil corfu--auto-complete-deferred ((#<window 194 on zero-inflated-poisson-identifiability.R> #<buffer zero-inflated-poisson-identifiability.R> 3918 121)) nil 512000 nil])

[jdtsmith]

corfu-make-frame recently had its final BUFFER argument removed. So in whatever advice you are using, you need instead to set the current buffer to BUFFER, and call make-frame without this argument.

[minad]

I believe it is this advice: #408 (reply in thread)

There's a certain hope that we can fix the child frame problem in EXWM directly, such that child frame packages don't have to maintain special EXWM support. See emacs-exwm/exwm#64.