build.gradle

plugins {
    id 'com.netflix.nebula.plugin-plugin' version '21.2.2'
    id "com.netflix.nebula.maven-publish" version "19.2.0"
    id "com.netflix.nebula.ivy-publish" version "19.2.0"
    id 'com.netflix.nebula.java-cross-compile' version '8.0.0' // adds support for github actions JDK install location
}


description 'Gradle plugins to do nothing'

dependencies {
    implementation 'com.google.guava:guava:28.+'
    implementation 'commons-logging:commons-logging:latest.release'
    implementation 'org.apache.commons:commons-math3:3.6.1'
}

gradlePlugin {
    plugins {
        nothingPlugin {
            id = 'com.netflix.nebula.nothing-plugin'
            displayName = 'Gradle nothing plugin'
            description = "Plugin that does nothing"
            implementationClass = 'nebula.plugin.nothing.NothingPlugin'
            tags.set(['nebula', 'nothing', 'example'])
        }
        moreNothingPlugin {
            id = 'com.netflix.nebula.more-nothing-plugin'
            displayName = 'Gradle more nothing plugin'
            description = "Another plugin that does nothing"
            implementationClass = 'nebula.plugin.nothing.MoreNothingPlugin'
            tags.set(['nebula', 'nothing', 'example'])
        }
    }
}


contacts {
    'nebula-plugins-oss@netflix.com' {
        moniker 'Nebula Plugins Maintainers'
        github 'nebula-plugins'
    }
}

publishing {
    repositories {
        maven {
            name 'distMaven'
            url = "$buildDir/maven-repo"
        }
    }
    publications {
        withType(MavenPublication) {
            pom {
                inceptionYear = '2014'
            }
        }
    }
}

dependencyLocking {
    lockAllConfigurations()
}

// for tests in this repo
test.dependsOn('generateDescriptorFileForPluginIvyPublication', 'generatePomFileForNebulaPublication', 'generatePomFileForPluginMavenPublication')