build.gradle

plugins {
    id 'org.springframework.boot' version '2.7.18'
    id 'io.spring.dependency-management' version '1.1.4'
    id 'java'
}

group = 'uk.nhs.prm.repo'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

//Without this task two jars are built, the additional "-plain.jar" is not needed
// for more details refer to: https://docs.spring.io/spring-boot/docs/current/gradle-plugin/reference/htmlsingle/#packaging-executable.and-plain-archives
jar {
    enabled = false
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-web'

    // CVE-2022-1471 false positive as spring boot uses safe constructor in snakeyaml
    // https://github.com/spring-projects/spring-boot/issues/33457
    implementation 'org.yaml:snakeyaml:2.2'

    implementation 'org.springdoc:springdoc-openapi-ui:1.6.14'
    implementation 'net.logstash.logback:logstash-logback-encoder:7.2'
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'

    // including workaround for bom mismatch which should be retired with full jackson-databind release
    components {
        withModule("com.fasterxml.jackson.core:jackson-databind") {
            allVariants {
                withDependencies {
                    removeAll {
                        it.name == "jackson-bom"
                    }
                }
            }
        }
    }
}

tasks.named('test') {
    useJUnitPlatform()
}