ezd2gm-choose

#!/usr/bin/env perl

# Single track, EZdrummer to general midi converter
#
# EZdrummer has more articulations than the limited range of general
# midi, so information is lost by doing this.
#
# Examples:
# perl ezd2gm-choose
# perl ezd2gm-choose --path=/midi/source --dest=/my/music
# perl ezd2gm-choose --midi=/some/midi/file.mid

use strict;
use warnings;

use File::Basename qw(basename);
use File::Find::Rule ();
use File::HomeDir ();
use Getopt::Long qw(GetOptions);
use MIDI ();
use Term::Choose qw(choose);

use constant DIR => '/Logic/Bounces'; # nb: personal desired subdirectory - YMMV

my %opts = (
    path => File::HomeDir->my_music . DIR, # source directory for midi files
    midi => undef,
    dest => File::HomeDir->my_music . DIR, # destination directory for processed midi
);
GetOptions( \%opts,
    'path=s',
    'midi=s',
    'dest=s',
) or die 'Error getting command options';

die "No such directory: $opts{path}" unless -d $opts{path};
die "No such directory: $opts{dest}" unless -d $opts{dest};

if ($opts{midi}) {
    die "No such file: $opts{midi}" unless -e $opts{midi};
}
else {
    # gather the midi files
    my @files = File::Find::Rule->file()
                                ->name(qr/\.midi?$/)
                                ->in($opts{path});
    unshift @files, 'Quit';
    my %files;
    my @names = map { basename($_) } @files;
    @files{@names} = @files;
    my $choice = choose(\@names, { prompt => 'Choose a MIDI file to process:' });
    exit if $choice eq 'Quit';
    $opts{midi} = $files{$choice};
}

# create the patch mapping
my %map;
while (my $line = readline(DATA)) {
    next if $line =~ /^\s*#/;
    chomp $line;
    $line =~ s/^\s*//;
    $line =~ s/\s*(?:#.*)?\s*$//;
    next unless $line;
    my ($key, $val) = split /\s*=>\s*/, $line;
    $map{$key} = $val;
}

my $opus = MIDI::Opus->new({ from_file => $opts{midi} });

my @events;

# process the midi
for my $t ( $opus->tracks ) {
    my $score_r = MIDI::Score::events_r_to_score_r($t->events_r);

    # map the note events
    for my $event (@$score_r) {
        # ['note', <start>, <duration>, <channel>, <note>, <velocity>]
        if ($event->[0] eq 'note') {
            $event->[4] = $map{ $event->[4] } ? $map{ $event->[4] } : $event->[4];
        }
        push @events, $event;
    }
}

# convert to a new opus
my $events_r = MIDI::Score::score_r_to_events_r(\@events);
my $track = MIDI::Track->new;
$track->events_r($events_r);
my $fresh = MIDI::Opus->new({ ticks => $opus->ticks, tracks => [ $track ] });

my $out = "$opts{dest}/ezd2gm-choose.mid";
$fresh->write_to_file($out);
print "Wrote $out\n";

__DATA__
# EZdrummer midinums => general midi patches
# closed hh
   11 => 42 # TODO which EZd articulation is this?
   22 => 42 # "
   61 => 42 # ...
   62 => 42
   63 => 42
   65 => 42
  122 => 42
# pedal hh
   10 => 44
   21 => 44
# open hh
    8 => 46
    9 => 46
   12 => 46
   13 => 46
   14 => 46
   15 => 46
   16 => 46
   17 => 46
   18 => 46
   19 => 46
   20 => 46
   24 => 46
   25 => 46
   26 => 46
   60 => 46
   64 => 46
  120 => 46
  121 => 46
  122 => 46
  123 => 46
  124 => 46
# crash 1
   55 => 49
   56 => 49
   83 => 49
   84 => 49
   86 => 49
   87 => 49
# crash 2
   27 => 57
   28 => 57
   49 => 57
   50 => 57
   88 => 57
   89 => 57
   90 => 57
   91 => 57
   92 => 57
   93 => 57
   94 => 57
# splash
   57 => 55
   58 => 55
   58 => 55
  100 => 55
  101 => 55
  103 => 55
  106 => 55
  107 => 55
# china
   95 => 52
   96 => 52
   98 => 52
   99 => 52
# ride 1
   29 => 51
   52 => 51
   54 => 51
   59 => 51
  104 => 51
  108 => 51
  111 => 51
  113 => 51
  116 => 51
  118 => 51
# ride 2
   52 => 59
   #59 => 59
  110 => 59
  115 => 59
  119 => 59
# ride bell
   30 => 53
   53 => 53
   85 => 53
   88 => 53
   90 => 53
   92 => 53
   93 => 53
   97 => 53
  100 => 53
  102 => 53
  105 => 53
  109 => 53
  112 => 53
  114 => 53
  117 => 53
# snare
    6 => 38
   33 => 38
   #38 => 38
   39 => 38
   40 => 38
   66 => 38
   68 => 38
   69 => 38
   70 => 38
   71 => 38
   76 => 38
  125 => 38
  126 => 38
# sidestick
   #37 => 37
   67 => 37
  127 => 37
# kick
   34 => 35
   #35 => 35
   #36 => 36
# high-mid tom
   #48 => 48
   81 => 48
   82 => 48
# low-mid tom
   #47 => 47
   79 => 47
   80 => 47
# low tom
   #45 => 45
   77 => 45
   78 => 45
# floortom 1
   #43 => 43
   74 => 43
   75 => 43
# floortom 2
   #41 => 41
   72 => 41
   73 => 41
# tambourine
    3 => 54
# maracas
    2 => 70
# hand clap
    1 => 39