build.gradle

/*
 * Copyright 2022-2024 Pranav Pandey
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

buildscript {
    ext.versions = [
            'compileSdk' : 35,
            'minSdk'     : 19,
            'targetSdk'  : 35,
            'buildTools' : '35.0.0',
            'gmsAds'     : '22.6.0',
            'kotlin'     : '1.9.24',
            'preferences': '2.4.0',
            'support'    : '6.4.0',
            'ump'        : '2.2.0'
    ]

    repositories {
        mavenCentral()
        google()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:8.5.1'
    }
}

plugins {
    id("io.github.gradle-nexus.publish-plugin") version "2.0.0"
}

allprojects {
    repositories {
        mavenCentral()
        google()
    }
}

tasks.register('clean', Delete) {
    delete rootProject.layout.buildDirectory
}

ext {
    projectName = 'dynamic-ads'
    projectDesc = 'A GDPR-compliant library to show ads via Google AdMob on Android.'
    versionDesc = 'A GDPR-compliant library to show ads via Google AdMob on Android ' +
            '4.1 (API 16) and above.'
    referenceTitle = 'Dynamic Ads API reference'

    siteUrl = 'https://github.com/pranavpandey/dynamic-ads'
    gitUrl = 'https://github.com/pranavpandey/dynamic-ads'
    issueUrl = 'https://github.com/pranavpandey/dynamic-ads/issues'
    githubUrl = 'pranavpandey/dynamic-ads'

    mavenRepo = 'android'
    mavenGroup = 'com.pranavpandey.android'
    mavenDir = 'com/pranavpandey/android'
    mavenArtifactId = 'dynamic-ads'
    mavenInceptionYear = '2022'
    mavenVersion = '1.4.0'
    mavenVersionCode = 8

    developerId = 'pranavpandey'
    developerName = 'Pranav Pandey'
    developerEmail = 'dynamic@pranavpandey.com'

    licenseName = 'The Apache Software License, Version 2.0'
    licenseUrl = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
    licenseDistribution = 'repo'
    allLicenses = ["Apache-2.0"]

    publication = 'local.properties'

    ext["signing.keyId"] = ''
    ext["signing.password"] = ''
    ext["signing.secretKeyRingFile"] = ''

    ossrhUsername = ''
    ossrhPassword = ''
    sonatypeStagingProfileId = ''
}

apply plugin: 'io.github.gradle-nexus.publish-plugin'

File publish = project.rootProject.file("${publication}")
if (publish.exists()) {
    Properties properties = new Properties()
    new FileInputStream(publish).withCloseable { is -> properties.load(is) }
    properties.each { name, value -> ext[name] = value }
}

nexusPublishing {
    repositories {
        sonatype {
            username = ossrhUsername
            password = ossrhPassword
            stagingProfileId = sonatypeStagingProfileId
        }
    }
}