Pitchbend noise

[jonvog]

Hello,

I'm very new to this so I could possibly do something wrong here. But I'm getting very noisy pb data. I'm aware of this example: https://tttapa.github.io/Control-Surface-doc/Doxygen/d3/d4e/Pitch-Bend-Potentiometer_8ino-example.html

I tried to dial in the "middle" setting, but no chance. I tested it also with large 100mm faders, but it's impossible to get a clear 0 / 8192 / middle value.

Maybe it is the wiring, but it actually should be ok, with CC data I don't get any noise (I know that it's 7 bit vs 14 bit but still).
Am I missing something here? Is there a way of making more "space" around 8192 to get rid of the noise when the pb wheel is untouched?

Thanks a lot!

[tttapa]

I'm using 60mm 10kΩ faders on an Arduino Leonardo and I have no noise at all. If you do get noise, this is probably a hardware issue (too high potentiometer resistance, noisy power supply, long wires, etc.)

The default PBPotentiometer class uses a resolution of 10 bits:

Control-Surface/src/MIDI_Outputs/PBPotentiometer.hpp

Lines 11 to 25 in feee931

	/**
	* @brief A class of MIDIOutputElement%s that read the analog input from a
	* **potentiometer or fader**, and send out 14-bit MIDI **Pitch Bend**
	* events.
	*
	* The analog input is filtered and hysteresis is applied for maximum
	* stability.
	* The actual precision is "only" 10 bits, because this is the resolution of the
	* built-in ADC, and this is the default resolution used by the Mackie Control
	* Universal protocol.
	* This version cannot be banked.
	*
	* @ingroup MIDIOutputElements
	*/
	class PBPotentiometer : public MIDIFilteredAnalog<PitchBendSender<10>> {

If you lower that number, you should see less noise. Other techniques to increase filtering are described here: https://forum.arduino.cc/index.php?topic=697324.msg4687860#msg4687860

I would try to fix this in hardware first, though.

[jonvog]

After a fair amount of trial and error, I figured where the mistake was: with PB I am apparently in the 16 bit realm and all the numbers were still CC 14 bit. I was already wondering why the numbers in the serial monitor were much higher than expected.
Anyway now it works wonderfully. Again a huge thank you Pieter for providing this library and for guiding me and everyone along. Arduino + MIDI is a journey, often fun, sometimes frustrating, but when a custom solution works in the end it is awesome.

This is the code that finally worked for me:

#include <Control_Surface.h> // Include the Control Surface library
 
// Instantiate a MIDI over USB interface.
USBMIDI_Interface midiusb;
HardwareSerialMIDI_Interface midiser = Serial1;

// Instantiate MIDI Pipes
MIDI_PipeFactory <1> pipes;
 
// Instantiate an array of CCPotentiometer objects
CCPotentiometer potentiometers[] = {
  {A0, 0x16}, // poti links oben, Controller number of the first potentiometer (hex) - CC22
  {A1, 0x17}, // poti rechts oben - CC23   
  {A2, 0x18}, // poti links unten - CC24
  {A3, 0x19}, // poti rechts unten - CC25
  {A4, 0x01}, // fader 1 - CC1
  {A5, 0x0B}, // fader 2 - CC11
  {A6, 0x15}, // fader 3 - CC21
  {A7, 0x02}, // fader 4 - CC2
};

// Instantiate the pitchbend potentiometer
PBPotentiometer pitchBend = {
  A8,        // Analog pin connected to potentiometer
  CHANNEL_1, // MIDI Channel 1 
};

// Mapping
constexpr analog_t minimumValue = 20200; // The filtered value read when potentiometer is at the 0% position
constexpr analog_t maximumValue = 46380; // The filtered value read when potentiometer is at the 100% position

// A mapping function to eliminate the dead zones of the potentiometer:
// Some potentiometers don't output a perfect zero signal when you move them to
// the zero position, they will still output a value of 1 or 2, and the same
// goes for the maximum position.

analog_t mappingFunction(analog_t raw) {
  // make sure that the analog value is between the minimum and maximum
  raw = constrain(raw, minimumValue, maximumValue);
  
  // map the value from [minimumValue, maximumValue] to [0, 65535]
  // Note: 65535 = 2^16 - 1 (the maximum value that can be represented by a 16-bit unsigned number)
  return map(raw, minimumValue, maximumValue, 0, 65535);
}

void setup() {
  pitchBend.map(mappingFunction); // Add the mapping function to the potentiometer
  midiusb.setAsDefault(); // (must be done before initializing Control Surface)
  midiser >> pipes >> midiusb; // all incoming midi from Serial is sent to USB
  Control_Surface.begin(); // Initialize Control Surface
  //Serial.begin(115200); // uncomment for using the serial monitor
}
 
void loop() {
  Control_Surface.loop(); // Update the Control Surface
  //Serial.println(pitchBend.getRawValue()); // print the raw PB value to the serial monitor
}

[tttapa]

Aha, I didn't connect the dots before, but the reason that you're seeing different behavior is the change you made to the analog filter settings. From the Arduino forum thread linked in my first reply:

Do keep in mind that if you change the analog filter settings, you have to change the constants in the mapping function. The formula for the maximum value is 2^B-1, where B = number of bits in the analog filter type - analog filter shift factor.
For the default values of ANALOG_FILTER_TYPE = uint16_t and ANALOG_FILTER_SHIFT_FACTOR = 2, B = 16 - 2 = 14, so the maximum value is 2¹⁴-1 = 16383.
You can get this value programatically using FilteredAnalog<>::getMaxRawValue().

I highly recommend using FilteredAnalog<>::getMaxRawValue().
It's on my todo list to use this in the map() examples as well, but I haven't had the time yet.

[jonvog]

oh yes, this makes total sense. so nothing to do with PB vs CC resolution (of course, since we are talking raw values here).
I'm not entirely sure how I would integrate your suggestion, but I will look into this and figure it out.
Also I could try to change the analog filter settings back to default, since the problem with noise most likely was there in the first place because of my crappy circuitry (which I could resolve with the added capacitor).

[tttapa]

You could use it like this:

// Mapping
constexpr unsigned long maxRawValue = FilteredAnalog<>::getMaxRawValue();
constexpr analog_t minimumValue = 20200 * maxRawValue / 65535; // The filtered value read when potentiometer is at the 0% position
constexpr analog_t maximumValue = 46380 * maxRawValue / 65535; // The filtered value read when potentiometer is at the 100% position

analog_t mappingFunction(analog_t raw) {
  // make sure that the analog value is between the minimum and maximum
  raw = constrain(raw, minimumValue, maximumValue);
  
  // map the value from [minimumValue, maximumValue] to [0, maxRawValue]
  return map(raw, minimumValue, maximumValue, 0, maxRawValue);
}

It might be a good idea to keep the changes you made to the filter settings. By restricting the range using the mapping function, you're also amplifying the noise, so the extra filtering is probably a good idea. (Your range is 2.5 times smaller, so your (relative) noise will also be 2.5 times higher.)

[jonvog]

amazing, thank you so much!

[josehdx]

Hello, I juts found this post as i am currently having some issues with the pitch bend setup. i think i have some "noise" as well, but i wonder if @jonvog can check my video and say if this is noise or not. i see constant reading with the MIDI monitor, and when i move the wheel, the Monitor crashes

https://youtu.be/ekfEOJ1Oc2M

Should i try the last code of @tttapa ?

where should i add that code?

This is my current code;

`#include <Control_Surface.h>

#include <AH/Hardware/MultiPurposeButton.hpp>

BluetoothMIDI_Interface midi;

// Instantiate a PBPotentiometer object
PBPotentiometer potentiometer {
A12, // Analog pin connected to potentiometer
CHANNEL_1, // MIDI Channel 1
};

MultiPurposeButton btn{

{0}

};

MultiPurposeButton btn2{

{35}

};

void setup() {
Control_Surface.begin();
btn.setLongPressDelay(550);
btn.setMultiPressDelay(400);
btn.begin();

btn2.setLongPressDelay(550);
btn2.setMultiPressDelay(400);
btn2.begin();
}

void loop() {

switch (btn.update()) {
case btn.None: break;
case btn.PressStart: break;

case btn.ShortPressRelease: Control_Surface.sendControlChange({MIDI_CC::General_Purpose_Controller_1, CHANNEL_1}, 0);
                            Control_Surface.sendControlChange({MIDI_CC::General_Purpose_Controller_1, CHANNEL_1}, 127);
        
      break;

case btn.LongPress: Control_Surface.sendControlChange({MIDI_CC::General_Purpose_Controller_1, CHANNEL_2}, 0);
Control_Surface.sendControlChange({MIDI_CC::General_Purpose_Controller_1, CHANNEL_2}, 127);

      break;

}

switch (btn2.update()) {
case btn2.None: break;
case btn2.PressStart: break;

case btn2.ShortPressRelease: Control_Surface.sendControlChange({MIDI_CC::General_Purpose_Controller_1, CHANNEL_3}, 0);
                            Control_Surface.sendControlChange({MIDI_CC::General_Purpose_Controller_1, CHANNEL_3}, 127);
            
      break;

case btn2.LongPress: Control_Surface.sendControlChange({MIDI_CC::General_Purpose_Controller_1, CHANNEL_4}, 0);
Control_Surface.sendControlChange({MIDI_CC::General_Purpose_Controller_1, CHANNEL_4}, 127);

      break;

}

Control_Surface.loop();

}`

Thank you