build.gradle

/*
 * Copyright (C) 2022 bytedance
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 *
 * Create Date : 2022/9/13
 */

apply plugin: 'com.android.library'
apply from: rootProject.file("gradle-config/constants.gradle")
def publishFile = rootProject.file("publish.gradle")
if (publishFile.exists()) {
    apply from: publishFile
}

android {
    compileSdkVersion project.ext.compileSdkVersion
    buildToolsVersion project.ext.buildToolsVersion

    resourcePrefix 'vevod_'

    defaultConfig {
        minSdkVersion project.ext.minSdkVersion
        targetSdkVersion project.ext.targetSdkVersion

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles "consumer-rules.pro"

        buildConfigField "String", "TTSDK_PLAYER_EDITION", "\"$project.ext.bytedance.ttsdkPlayerEdition\""
        buildConfigField "String", "TTSDK_PLAYER_EXTENSIONS", "\"$project.ext.bytedance.ttsdkPlayerExtensions\""
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
}

dependencies {
    testImplementation "junit:junit:${project.ext.junit}"
    androidTestImplementation "androidx.test.ext:junit:${project.ext.androidxTestJunit}"
    androidTestImplementation "androidx.test.espresso:espresso-core:${project.ext.androidxTestEspressoCore}"

    implementation "androidx.appcompat:appcompat:${project.ext.androidxAppcompat}"

    implementation "com.bytedanceapi:ttsdk-player_${project.ext.bytedance.ttsdkPlayerEdition}:${project.ext.bytedance.ttsdkVersion}"
    if (project.ext.bytedance.ttsdkPlayerEdition == "premium") {
        if (project.ext.bytedance.ttsdkPlayerExtensions.contains("super_resolution")) {
            // + super resolution sdk
            implementation "com.bytedanceapi:ttsdk-ttbmf:${project.ext.bytedance.ttsdkVersion}"
        }
        if (project.ext.bytedance.ttsdkPlayerExtensions.contains("abr")) {
            // + abr sdk
            implementation "com.bytedanceapi:ttsdk-ttabr:${project.ext.bytedance.ttsdkVersion}"
        }
        if (project.ext.bytedance.ttsdkPlayerExtensions.contains("ecdn")) {
            // ecdn
            implementation "com.bytedanceapi:ttsdk-ttpcdn:${project.ext.bytedance.ttsdkVersion}"
        }
    }
    implementation "com.bytedanceapi:ttvideoengine-debugtool:0.3.0.1"
    implementation "com.bytedance.applog:RangersAppLog-Lite-cn:${project.ext.bytedance.applogVersion}"
    implementation "com.squareup.okhttp3:okhttp:${project.ext.okhttp}"

    implementation "com.google.code.gson:gson:2.8.9"

    implementation project(':vod-playerkit:vod-player')
    implementation project(':vod-playerkit:vod-player-utils')
}