stap_base.stp

#! /bin/sh

# Copyright 2015 vonnyfly(lifeng1519@gmail.com)

# suppress some run-time errors here for cleaner output
//bin/true && exec stap  --all-modules --suppress-handler-errors --skip-badvars $0 ${1+"$@"}


/* configuration options; set these with stap -G */
global g_extra = 1
global black_lists
global g_incalls
function trace(entry_p, extra) {
    if (g_extra == 0) extra = ""
    if (tid() in g_incalls)
      printf("%s%s%s %s\n",
         thread_indent (entry_p),
         (entry_p>0?"->":"<-"),
         ppfunc (),
         extra)
}


probe $2.call {
  if (execname() in black_lists) next
  trace(1, $$parms)
}
probe $2.return {
  if (execname() in black_lists) next
  trace(-1, $$return)
}

probe $1.call   {
  black_lists["stapio"] = 1
  black_lists["swapper/0"] = 1
  g_incalls[tid()] = 1
  trace(1, $$parms)
}
probe $1.return {
  trace(-1, $$return)
  delete g_incalls[tid()]
  printf("\nkernel backtrace:\n")
  print_backtrace()
  printf("---------------------------------------------------------\n")
}