either.zp

(load "monads/monads.zp")

(define (monads:left err) "build a left instance of the either monad"
  (monads:generic err :left (lambda (val) (monads:left val)) (lambda (f) (monads:left err))))

(define (monads:right val) "build a right instance of the either monad"
  (monads:generic val :right (lambda (val) (monads:right val)) (lambda (f) (f val))))

(define (monads:left? monad) "is monad instance left?"
  (eq? (monads:get-type monad) :left))

(define (monads:right? monad) "is monad instance right?"
  (eq? (monads:get-type monad) :right))

(define (monads:partition-eithers monads)
  "returns a list of two lists, the first being the left values, the second being the right ones"
  (list (monads:lefts monads) (monads:rights monads)))

(define (monads:lefts monads)
  "returns all the left elements in the list"
  (filter monads:left? monads))

(define (monads:rights monads)
  "returns all the right elements in the list"
  (filter monads:right? monads))

(define-syntax monads:either
  (syntax-rules (=>)
    ((monads:either monad (x => r) (y => l))
      (if (monads:right? monad)
        (let ((x (monads:get-val! monad)))
          r)
        (let ((y (monads:get-val! monad)))
          l)))
    ((monads:either x)
      (error "Syntax error in call to monads:either, called with:" 'x ";\ncorrect form is (monad (var => on-right) (err-var => on-left))"))
    ((monads:either x ...)
      (error "Syntax error in call to monads:either, called with:" 'x ";\ncorrect form is (monad (var => on-right) (err-var => on-left))"))))