nixos/services/networking/g3proxy: init

This adds a simple hardened systemd-based module for g3proxy, a generic purpose forward proxy. Change-Id: I8c6e5d2cc8a9faa2aea8c5df3af56756ffed542d Signed-off-by: Raito Bezarius <[email protected]>
NixOS · Jan 30, 2025 · 68f0fd8 · 68f0fd8
1 parent c3722e5
commit 68f0fd8
Show file tree

Hide file tree

Showing 2 changed files with 94 additions and 0 deletions.
diff --git a/nixos/modules/module-list.nix b/nixos/modules/module-list.nix
@@ -1266,6 +1266,7 @@
   ./services/networking/spacecookie.nix
   ./services/networking/spiped.nix
   ./services/networking/squid.nix
+  ./services/networking/g3proxy.nix
   ./services/networking/ssh/sshd.nix
   ./services/networking/sslh.nix
   ./services/networking/strongswan-swanctl/module.nix

diff --git a/nixos/modules/services/networking/g3proxy.nix b/nixos/modules/services/networking/g3proxy.nix
@@ -0,0 +1,93 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.services.g3proxy;
+
+  inherit (lib)
+    mkPackageOption
+    mkEnableOption
+    mkOption
+    mkIf
+    literalExpression
+    ;
+
+  settingsFormat = pkgs.formats.yaml { };
+in
+{
+  options.services.g3proxy = {
+    enable = mkEnableOption "g3proxy, a generic purpose forward proxy";
+
+    package = mkPackageOption pkgs { } "g3proxy";
+
+    settings = mkOption {
+      type = settingsFormat.type;
+      default = { };
+      example = literalExpression ''
+        {
+          server = [{
+            name = "test";
+            escaper = "default";
+            type = "socks_proxy";
+            listen = {
+              address = "[::]:10086";
+            };
+          }];
+        }
+      '';
+      description = ''
+        Settings of g3proxy.
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    systemd.services.g3proxy = {
+      description = "g3proxy server";
+      wantedBy = [ "multi-user.target" ];
+      after = [ "network.target" ];
+
+      serviceConfig = {
+        ExecStart =
+          let
+            g3proxy-yaml = settingsFormat.generate "g3proxy.yaml" cfg.settings;
+          in
+          "${cfg.package}/bin/g3proxy --config-file ${g3proxy-yaml}";
+
+        WorkingDirectory = "/var/lib/g3proxy";
+        StateDirectory = "g3proxy";
+        RuntimeDirectory = "g3proxy";
+        DynamicUser = true;
+
+        RuntimeDirectoryMode = "0755";
+        PrivateTmp = true;
+        DevicePolicy = "closed";
+        LockPersonality = true;
+        MemoryDenyWriteExecute = true;
+        PrivateUsers = true;
+        ProtectHome = true;
+        ProtectHostname = true;
+        ProtectKernelLogs = true;
+        ProtectKernelModules = true;
+        ProtectKernelTunables = true;
+        ProtectControlGroups = true;
+        ProtectSystem = "strict";
+        ProcSubset = "pid";
+        RestrictNamespaces = true;
+        RestrictRealtime = true;
+        RemoveIPC = true;
+        SystemCallArchitectures = "native";
+        UMask = "0077";
+        RestrictAddressFamilies = [
+          "AF_UNIX"
+          "AF_INET"
+          "AF_INET6"
+        ];
+        RestrictSUIDSGID = true;
+      };
+    };
+  };
+}