flake: groundwork for VM tests

Removes basic check packages in favor of proper VM testing infrastructure.

flake.nix

@@ -5,14 +5,23 @@
     self,
     nixpkgs,
     ...
-  } @ inputs: {
+  }: let
+    forAllSystems = nixpkgs.lib.genAttrs ["x86_64-linux" "aarch64-linux"];
+  in {
     nixosModules = {
       hjem = ./modules/nixos.nix;
       default = self.nixosModules.hjem;
     };
 
-    checks = import ./checks {inherit inputs;};
+    checks = forAllSystems (system: let
+      checkArgs = {
+        inherit self;
+        pkgs = nixpkgs.legacyPackages.${system};
+      };
+    in {
+      hjem-basic = import ./tests/basic.nix checkArgs;
+    });
 
-    formatter = nixpkgs.lib.genAttrs ["x86_64-linux" "aarch64-linux"] (system: nixpkgs.legacyPackages.${system}.alejandra);
+    formatter = forAllSystems (system: nixpkgs.legacyPackages.${system}.alejandra);
   };
 }

tests/basic.nix

@@ -0,0 +1,38 @@
+let
+  userHome = "/home/alice";
+in
+  (import ./lib.nix) {
+    name = "hjem-basic";
+    nodes = {
+      machine = {
+        self,
+        pkgs,
+        ...
+      }: {
+        imports = [self.nixosModules.hjem];
+
+        users.groups.alice = {};
+        users.users.alice = {
+          isNormalUser = true;
+          home = userHome;
+        };
+
+        homes = {
+          alice = {
+            directory = userHome;
+            files.".config/foo".text = "Hello world!";
+            packages = [pkgs.hello];
+          };
+        };
+      };
+    };
+
+    testScript = ''
+      # Start all machines
+      start_all()
+
+      # wait for our service to start
+      machine.wait_for_unit("systemd-tmpfiles-setup.service")
+      output = machine.succeed("ls ${userHome}/.config/foo")
+    '';
+  }

tests/lib.nix

@@ -0,0 +1,17 @@
+# The first argument to this function is the test module itself
+test: {
+  pkgs,
+  self,
+}: let
+  inherit (pkgs) lib;
+  nixos-lib = import (pkgs.path + "/nixos/lib") {};
+in
+  (nixos-lib.runTest {
+    hostPkgs = pkgs;
+    defaults.documentation.enable = lib.mkDefault false;
+
+    node.specialArgs = {inherit self;};
+    imports = [test];
+  })
+  .config
+  .result