flake: groundwork for VM tests

.github/dependabot.yml

@@ -0,0 +1,11 @@
+version: 2
+updates:
+  - package-ecosystem: github-actions
+    directory: "/"
+    schedule:
+      interval: daily
+    open-pull-requests-limit: 15
+    reviewers:
+      - NotAShelf
+    assignees:
+      - NotAShelf

.github/workflows/vm-tests.yml

@@ -0,0 +1,41 @@
+name: Run VM tests
+
+on:
+  workflow_call:
+  pull_request:
+  push:
+    branches:
+      - main
+jobs:
+  nix:
+    strategy:
+      matrix:
+        system:
+          - x86_64-linux
+          - aarch64-linux
+
+    runs-on: ubuntu-latest
+    steps:
+      - name: "Set up QEMU support"
+        uses: docker/setup-qemu-action@v3
+        with:
+          platforms: arm64
+
+      - name: Install Nix
+        uses: DeterminateSystems/nix-installer-action@main
+        with:
+          diagnostic-endpoint: "" # no personalized self-merges tyvm.
+          logger: pretty
+          extra-conf: |
+            experimental-features = nix-command flakes
+            allow-import-from-derivation = false
+            extra-platforms = aarch64-linux
+
+      - name: Checkout
+        uses: actions/checkout@v4
+
+      # For now, only a basic test exists and thus we only build that. In the future
+      # we may consider chaining matrix.system and matrix.check to build more tests
+      # for each individual system.
+      - name: Build packages
+        run: nix build -L .#checks.${{ matrix.system }}.hjem-basic -v

.gitignore

@@ -0,0 +1,3 @@
+# Nix build/test artifacts
+.nixos-test-history
+result*

flake.nix

@@ -5,14 +5,23 @@
     self,
     nixpkgs,
     ...
-  } @ inputs: {
+  }: let
+    forAllSystems = nixpkgs.lib.genAttrs ["x86_64-linux" "aarch64-linux"];
+  in {
     nixosModules = {
       hjem = ./modules/nixos.nix;
       default = self.nixosModules.hjem;
     };
 
-    checks = import ./checks {inherit inputs;};
+    checks = forAllSystems (system: let
+      checkArgs = {
+        inherit self;
+        pkgs = nixpkgs.legacyPackages.${system};
+      };
+    in {
+      hjem-basic = import ./tests/basic.nix checkArgs;
+    });
 
-    formatter = nixpkgs.lib.genAttrs ["x86_64-linux" "aarch64-linux"] (system: nixpkgs.legacyPackages.${system}.alejandra);
+    formatter = forAllSystems (system: nixpkgs.legacyPackages.${system}.alejandra);
   };
 }

tests/basic.nix

@@ -0,0 +1,55 @@
+let
+  userHome = "/home/alice";
+in
+  (import ./lib.nix) {
+    name = "hjem-basic";
+    nodes = {
+      node1 = {
+        self,
+        pkgs,
+        ...
+      }: {
+        imports = [self.nixosModules.hjem];
+
+        users.groups.alice = {};
+        users.users.alice = {
+          isNormalUser = true;
+          home = userHome;
+          password = "";
+        };
+
+        homes = {
+          alice = {
+            enable = true;
+            packages = [pkgs.hello];
+            files.".config/foo" = {
+              text = "Hello world!";
+            };
+          };
+        };
+
+        # Also test systemd-tmpfiles internally
+        systemd.user.tmpfiles = {
+          rules = [
+            "d %h/user_tmpfiles_created"
+          ];
+
+          users.alice.rules = [
+            "d %h/only_alice"
+          ];
+        };
+      };
+    };
+
+    testScript = ''
+      machine.succeed("loginctl enable-linger alice")
+      machine.wait_until_succeeds("systemctl --user --machine=alice@ is-active systemd-tmpfiles-setup.service")
+
+      # Test file created by Hjem
+      machine.succeed("[ -L ~alice/.config/foo ]")
+
+      # Test regular files, created by systemd-tmpfiles
+      machine.succeed("[ -d ~alice/user_tmpfiles_created ]")
+      machine.succeed("[ -d ~alice/only_alice ]")
+    '';
+  }

tests/lib.nix

@@ -0,0 +1,17 @@
+# The first argument to this function is the test module itself
+test: {
+  pkgs,
+  self,
+}: let
+  inherit (pkgs) lib;
+  nixos-lib = import (pkgs.path + "/nixos/lib") {};
+in
+  (nixos-lib.runTest {
+    hostPkgs = pkgs;
+    defaults.documentation.enable = lib.mkDefault false;
+
+    node.specialArgs = {inherit self;};
+    imports = [test];
+  })
+  .config
+  .result