Add Log tests

lib/LiBro/Log.hs

@@ -3,7 +3,8 @@ module LiBro.Log where
 import Text.Printf
 import Data.Time.Clock
 
-data LogLevel   = INFO | WARNING | ERROR | FATAL deriving (Eq, Ord, Show)
+data LogLevel   = INFO | WARNING | ERROR | FATAL
+                  deriving (Eq, Ord, Enum, Bounded, Show)
 type LogSource  = String
 type LogMessage = String
 data Log = Log

libro-backend.cabal

@@ -79,6 +79,7 @@ test-suite libro-backend-test
   other-modules:      LiBro.TestUtil
                     , LiBro.TestUtilSpec
                     , LiBro.ConfigSpec
+                    , LiBro.LogSpec
                     , LiBro.DataSpec
                     , LiBro.Data.StorageSpec
                     , LiBro.Data.SafeTextSpec
@@ -102,5 +103,6 @@ test-suite libro-backend-test
                     , silently
                     , temporary
                     , text
+                    , time
                     , transformers
                     , vector

test/LiBro/LogSpec.hs

@@ -0,0 +1,57 @@
+module LiBro.LogSpec where
+
+import Test.Hspec
+import Test.QuickCheck
+import Test.Hspec.QuickCheck
+
+import LiBro.Base
+import LiBro.Log
+import Data.Default
+import Data.Time.Clock
+import Data.Tuple.Extra
+
+spec :: Spec
+spec = describe "Logging" $ do
+  format
+  collection
+
+format :: Spec
+format = describe "Log format" $ do
+
+  describe "Show instance" $ do
+    now <- runIO getCurrentTime
+    it "Correct log stringification" $
+      show (Log now WARNING "foo" "bar")
+        `shouldBe` "WARNING [" ++ show now ++ "] (foo): bar"
+
+  describe "Within LiBroIO monad" $ do
+    now <- runIO getCurrentTime
+    (_, logs) <- runIO $ runLiBroIOLogs def $ addLog WARNING "foo" "bar"
+    it "Exactly one log" $ length logs == 1
+    let l = head logs
+    it "Correct log level"    $ level   l `shouldBe` WARNING
+    it "Correct log source"   $ source  l `shouldBe` "foo"
+    it "Correct log message"  $ message l `shouldBe` "bar"
+    it "Logged time is close enough" $
+      (time l `diffUTCTime` now) `shouldSatisfy` (< 0.42)
+
+genLogData :: Gen (LogLevel, LogSource, LogMessage)
+genLogData = (,,) <$> chooseEnum (minBound, maxBound)
+                  <*> arbitrary
+                  <*> arbitrary
+
+collection :: Spec
+collection = describe "Collection of logs" $ do
+
+  prop "Correct list of logs" $
+    forAll (listOf genLogData) $ \lds -> ioProperty $ do
+      (_, logs) <- runLiBroIOLogs def $ uncurry3 addLog `mapM_` lds
+      let logTuples = map ((,,) <$> level <*> source <*> message) logs
+      logTuples `shouldBe` lds
+
+  prop "Ordered by time" $
+    forAll (listOf genLogData) $ \lds -> ioProperty $ do
+      (_, logs) <- runLiBroIOLogs def $ uncurry3 addLog `mapM_` lds
+      time <$> logs `shouldSatisfy` isSorted
+
+  where isSorted = and . (zipWith (<=) <*> tail)

test/run-all-tests.hs

@@ -3,6 +3,7 @@ module Main where
 import Test.Hspec
 import LiBro.Util
 
+import qualified LiBro.LogSpec            as Log
 import qualified LiBro.DataSpec           as Data
 import qualified LiBro.Data.SafeTextSpec  as Data.SafeText
 import qualified LiBro.Data.StorageSpec   as Data.Storage
@@ -24,6 +25,7 @@ withLibreOffice runTests = do
 
 main :: IO ()
 main = hspec $ aroundAll_ withLibreOffice $ do
+  Log.spec
   Data.spec
   Data.SafeText.spec
   Data.Storage.spec