Skip to content
New issue

Have a question about this project? Sign up for a free GitHub account to open an issue and contact its maintainers and the community.

By clicking “Sign up for GitHub”, you agree to our terms of service and privacy statement. We’ll occasionally send you account related emails.

Already on GitHub? Sign in to your account

feat: respect system-configured interface font #182

Closed
wants to merge 2 commits into from
Closed
Changes from 1 commit
Commits
File filter

Filter by extension

Filter by extension

Conversations
Failed to load comments.
Loading
Jump to
Jump to file
Failed to load files.
Loading
Diff view
Diff view
Prev Previous commit
chore(nix): add flake with development shell and package
  • Loading branch information
HeitorAugustoLN committed Jan 25, 2025

Verified

This commit was signed with the committer’s verified signature.
zner0L Lorenz Sieben
commit b321bc5d407bfa7b86c5f96d489d9c34ee1629c9
58 changes: 58 additions & 0 deletions flake.lock

Some generated files are not rendered by default. Learn more about how customized files appear on GitHub.

34 changes: 34 additions & 0 deletions flake.nix
Original file line number Diff line number Diff line change
@@ -0,0 +1,34 @@
{
inputs = {
flake-parts.url = "github:hercules-ci/flake-parts";
nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
};

outputs =
inputs:
inputs.flake-parts.lib.mkFlake { inherit inputs; } {
systems = [
"aarch64-linux"
"x86_64-linux"
];

perSystem =
{ pkgs, self', ... }:
{
devShells.default = pkgs.mkShell {
nativeBuildInputs = with pkgs; [
cargo
clippy
rustc
rustfmt
];

strictDeps = true;
};
packages = {
default = self'.packages.cosmic-greeter;
cosmic-greeter = pkgs.callPackage ./package.nix { };
};
};
};
}
113 changes: 113 additions & 0 deletions package.nix
Original file line number Diff line number Diff line change
@@ -0,0 +1,113 @@
# Based on lilyinstarlight's work on:
# https://github.com/lilyinstarlight/nixos-cosmic/blob/main/pkgs/cosmic-greeter/package.nix
{
lib,
rustPlatform,
cmake,
coreutils,
just,
libinput,
linux-pam,
stdenv,
udev,
xkeyboard_config,
wayland,
vulkan-loader,
xorg,
libGL,
libxkbcommon,
makeBinaryWrapper,
pkg-config,
cosmic-icons,
}:
rustPlatform.buildRustPackage {
pname = "cosmic-greeter";
version = "1.0.0-alpha.5.1";

src = lib.fileset.toSource {
root = ./.;
fileset = lib.fileset.difference ./. (
lib.fileset.unions [
(lib.fileset.maybeMissing ./result)
(lib.fileset.maybeMissing ./target)
(lib.fileset.maybeMissing ./.git)
(lib.fileset.fileFilter (
file:
builtins.elem file.name [
"flake.nix"
"flake.lock"
"LICENSE"
"README.md"
".gitignore"
".gitattributes"
"package.nix"
]
) ./.)
]
);
};

nativeBuildInputs = [
cmake
just
makeBinaryWrapper
pkg-config
rustPlatform.bindgenHook
];

buildInputs = [
libinput
linux-pam
udev
wayland
vulkan-loader
xorg.libX11
xorg.libXcursor
xorg.libXi
xorg.libxcb
libGL
libxkbcommon
];

useFetchCargoVendor = true;
cargoHash = "sha256-nmkM/Jm2P5ftZFfzX+O1Fe6eobRbgBkajZsbyI67Zfw=";
cargoBuildFlags = [ "--all" ];

dontUseJustBuild = true;
dontUseJustCheck = true;

justFlags = [
"--set"
"prefix"
(placeholder "out")
"--set"
"bin-src"
"target/${stdenv.hostPlatform.rust.cargoShortTarget}/release/cosmic-greeter"
"--set"
"daemon-src"
"target/${stdenv.hostPlatform.rust.cargoShortTarget}/release/cosmic-greeter-daemon"
];

postPatch = ''
substituteInPlace src/greeter.rs --replace-fail '/usr/bin/env' '${lib.getExe' coreutils "env"}'
'';

postInstall = ''
wrapProgram "$out/bin/cosmic-greeter" \
--set-default X11_BASE_RULES_XML "${xkeyboard_config}/share/X11/xkb/rules/base.xml" \
--set-default X11_EXTRA_RULES_XML "${xkeyboard_config}/share/X11/xkb/rules/base.extras.xml" \
--suffix XDG_DATA_DIRS : "${cosmic-icons}/share" \
--prefix LD_LIBRARY_PATH : "${
lib.makeLibraryPath [
xorg.libX11
xorg.libXcursor
xorg.libXi
xorg.libxcb
libGL
libxkbcommon
wayland
vulkan-loader
]
}"
'';
}